home *** CD-ROM | disk | FTP | other *** search
/ Internet Info 1994 March / Internet Info CD-ROM (Walnut Creek) (March 1994).iso / networking / terms / kermit / a / msxp98.asm < prev    next >
Encoding:
Assembly Source File  |  1991-04-18  |  81.1 KB  |  3,408 lines
  1.          name    msxp98
  2. ; File MSXP98.ASM
  3. ; NEC PC-9801 MS DOS Kermit module.
  4. ;
  5. ; Last edit: 17 Apr 1991
  6. ; 17 Apr 1991 Joe Doupnik's modifications are added. -> KEK v1.22
  7. ; 05 Apr 1991 KEK v1.21 for MS-Kermit v3.10
  8. ;             correct flow control mismatch.
  9. ;             added pcwtst for correct pcwait.
  10. ; 25 Jul 1990 KEK v1.20 for MS-Kermit v3.02
  11. ; 24 Sep 1989 KEK v1.16 (added VT52 mode).
  12. ; 04 Aug 1989 Fixed wrong ESC M (Reverse index) behavior (in MSYP98.ASM).
  13. ; 30 May 1989 ESC [ 0 m resets to color to default (color in command mode).
  14. ; 25 Apr 1989 KEK v1.15 .
  15. ; 24 Apr 1989 Fixed bug of cooked log for dumb terminal emulator.
  16. ; 21 Apr 1989 Raw mode logging is moved to outside the terminal emulator.
  17. ; 16 Apr 1989 Cooked log in VT100 mode is installed.
  18. ; 01 Mar 1989 Bug on JIS-7 input when local echo is on.
  19. ; 24 Feb 1989 start test of the device port. v1.15 alpha
  20. ; 13 Feb 1989 domode is called when really necessary.
  21. ;             graphic display on when exit.
  22. ; 08 Feb 1989 Call getbaud in lclini.
  23. ; 04 Feb 1989 Bug report from Yoro@Kyoto.Univ. SHOW MODEM becomes mad
  24. ;             when modem is not ready.  This was bug in getmodem.
  25. ; 28 Jan 1989 KEK v1.14, + MS-Kermit 2.23/A
  26. ; 17 Dec 1988 AUTOTEK feature is completely removed. Use eneble/disable Tek.
  27. ; 08 Sep 1988 JIS-7 code for 'Kanji-send' is installed.
  28. ;             The original idea and its code is due to Ogawa, NTT software-lab.
  29. ;             Thanx for cooperation !
  30. ; 16 Jul 1988 Keyboard kanji translation comes into chrout to work with
  31. ;             SET KEY command.
  32. ; 14 Jul 1988 V2.31
  33. ;             old global variable PCNET is now local variable
  34. ;             local termination pointer NETDONE is renamed LCLEXIT
  35. ;             GETMODEM is added as a dummy routine (from MSXGEN.ASM)
  36. ;             Ungermann-Bass port name is UB-NETCI
  37. ; 25 Jun 1988 Ungermann-Bass PC-NIU N98 support in NETCI mode
  38. ; 15 Jun 1988 V1.00
  39. ; 06 Jun 1988 show modem is installed
  40. ; 23 May 1988 added KEYCLICK, AUTOTEK features
  41. ; 19 May 1988 become v2.27(A) level (TEK4014, VT100)
  42. ; 18 May 1988 Keyboard routine for VT100 is installed.
  43. ; 16 May 1988 Works with v2.27(A) VT100 output routine.
  44. ; 15 May 1988 Fixed bug in SERINI.
  45. ; 14 May 1988 Works with dumb terminal emulator !
  46. ; 12 May 1988 start coding based on MSXGEN.ASM by H.Fujii
  47.  
  48.         public  serini, serrst, clrbuf, outchr, coms, vtstat
  49.         public  ctlu, cmblnk, locate, lclini, prtchr, clearl
  50.         public  baudst, getbaud, beep, trnprs, termtb
  51.         public    setchtab
  52.         public  count, xofsnt, puthlp, putmod, clrmod, poscur
  53.         public  sendbr, sendbl, term, machnam, setktab, setkhlp, showkey
  54.         public  ihosts, ihostr, dtrlow, serhng, dumpscr
  55.         public    bdtab, comptab, portval
  56.         public  chrout, cstatus, cquit, cquery, chang   ; kbd action verbs
  57.         public  snull, kdos, klogof, klogon
  58.     public    trnmod
  59.         public    shomodem, getmodem, mdmhand
  60.     public    pf1, pf2, pf3, pf4
  61.     public    kp0, kp1, kp2, kp3, kp4, kp5, kp6, kp7, kp8, kp9
  62.     public    decf6, decf7, decf8, decf9, decf10, decf11, decf12, decf13
  63.     public    decf14, dechelp, decdo, decf17, decf18, decf19, decf20
  64.     public    decfind, decinsert, decremove, decselect
  65.     public    decprev, decnext
  66.     public    kpmins, kpcoma, kpentr, kpdot
  67.     public    uparrw, dnarrw, lfarrw, rtarrw
  68.         public    keyinchg
  69.     public    vtchg, vtreset, vtrmac, vtsmac
  70.         public    upone, dnone, upscn, dnscn
  71.         public    gupone, gdnone
  72.         public    prtscn
  73.         public    outcapt
  74.         public    set_cur_color
  75.  
  76.     public    cpu_clock, vtgrph_flg, vttest_flg
  77.     public    curkey_mode, keypad_mode, display_mode
  78.     public    kanji_rmode, kanji_smode
  79.     public    kanji_rcode, kanji_scode
  80.     public    keyin_dos, vt100_cursr
  81.     public  vt100_flags, vt100_pflag, vt100_lflag, vt100_gflag
  82.     public    vt_ourarg
  83.     public    scn_color, def_color
  84.     public    extmacro, vtmacname, vtmaclen
  85.         include mssdef.h
  86.         include    msxp98.h
  87.  
  88. CHR_GS    equ    1Dh
  89. CHR_CAN    equ    18h
  90.  
  91. false   equ     0
  92. true    equ     1
  93. instat  equ     6
  94. prtscr  equ     80h                     ; print screen pressed
  95.  
  96. ;
  97. ; Ungermann-Bass PC-NIU N98 command interpreter interface
  98. ; CALL    AH -- Function number
  99. ;         AL -- Port number relative to 0
  100. ;         CX -- may be a counter, CL is used as a subfunction for control
  101. ;      ES:BX -- may be a buffer address
  102.  
  103. NETCI_PORT    equ    0        ; NETCI port number
  104.  
  105. NETCI_INT    equ    06Bh        ; Software interrupt vector# for NETCI
  106. NETCI_OPEN    equ    2        ; NETCI open function
  107. NETCI_CLOSE    equ    3        ; NETCI close function
  108. NETCI_READ    equ    1        ; NETCI read function
  109. NETCI_WRITE    equ    0        ; NETCI write function
  110. NETCI_CNTL    equ    6        ; NETCI control function
  111. NETCI_STATUS    equ    7        ; NETCI status function
  112. NETCI_RBRK    equ    8        ; NETCI read break function
  113.  
  114. NETCI_BRK    equ    2        ; NETCI control function, BREAK
  115. NETCI_DIS    equ    4        ; NETCI control function, DISCONNECT
  116. NETCI_HLD    equ    6        ; NETCI control function, HOLD
  117.  
  118. ; Buffer size for Network transfer
  119.  
  120. NETBUFLEN    equ    256
  121.  
  122. ; port assignments for 8251 serial controllers
  123. ;
  124. ;== PORT 1 ==
  125.  
  126. mndata    equ    30h
  127. mnst1a    equ    32h
  128. mncmda    equ    32h
  129.  
  130. mnmska    equ    35h    ; mask set
  131. mnrdsa    equ    33h    ; read signal
  132.  
  133. ;== PORT 2 ==
  134.  
  135. mndatb    equ    0B1h
  136. mnst1b    equ    0B3h
  137. mncmdb    equ    0B3h
  138.  
  139. mnmskb    equ    0B0h
  140. mnrdsb    equ    0B0h    ; read signal
  141.  
  142. ;== PORT 3 ==
  143.  
  144. mndatc    equ    0B9h
  145. mnst1c    equ    0BBh
  146. mncmdc    equ    0BBh
  147.  
  148. mnmskc    equ    0B2h    ; mask set
  149. mnrdsc    equ    0B2h    ; read signal
  150.  
  151. ; Status bits from austt
  152.  
  153. txrdy    equ    01h
  154. rxrdy    equ    02h
  155.  
  156. ; Command values for mncmd
  157.  
  158. ccmd    equ    37H        ; RTS & DTR high, RX & TX enabled, reset ERR
  159. cbrk    equ    08H        ; break enabled
  160. chng    equ    10H        ; RTS & DTR low, RX & TX disabled, reset ERR
  161. cmode    equ    40H        ; enable mode reset
  162. mmode    equ    4EH        ; 16x rate, 8 data, no parity, 1 stop
  163.  
  164. ; Mask values for mnmsk
  165.  
  166.  
  167. txmsk    equ    04H        ; disables transmit ready interrupt
  168. rxmsk    equ    01H        ; disables receive ready interrupt
  169. tbemsk    equ    02H        ; disables transmit buffer empty interrupt
  170.  
  171.  
  172. ; port assignments for 8253 timers
  173.  
  174. ;        Standard interface
  175.  
  176. tmdata    equ    75H        ; data port
  177. tmcmda    equ    77H        ; command port  (Was 27H Ian 10/27/84)
  178.  
  179.  
  180. ; values for tmcmd which select timer channel and mode
  181.  
  182. tmsela    equ    0B6H        ; Channel 2, mode 3 (standard port)
  183.  
  184. ; Baudrate
  185.  
  186. B9600    equ    13
  187.  
  188. ; Modem information
  189.  
  190. mdminfo struc
  191. mddat   dw      0
  192. mdstat  dw      0
  193. mdcom   dw      0
  194. mden    db      0
  195. mddis   db      0
  196. mdmeoi  db      0
  197. mdintv  dw      0
  198. mdminfo ends
  199.  
  200. ; Timer information for current port selection
  201.  
  202. tmrinfo    struc
  203. tmdat    dw    0        ; data port
  204. tmcmd    dw    0        ; command port
  205. tmsel    db    0        ; byte which selects channel and mode
  206. tmrinfo    ends
  207.  
  208. ; Modem information for current port selection
  209.  
  210. ; port assignments for 8259 interrupt controllers
  211.  
  212. ;        Standard interface
  213.  
  214. intcmda    equ    00H        ; Command port (master controller)
  215. intmska    equ    02H        ; Mask port
  216. ictmsk    equ    01H        ; Timer interrupt mask (to master)
  217. icsmska    equ    10H    ; Standard serial interrupt mask (to master)
  218. icsvcta equ    0CH    ;Interrupt vector for standard interface
  219.  
  220. icEOI    equ    20H        ; generic end of interrupt for intcmd
  221.  
  222. ; miscellaneous constants
  223.  
  224. mntrgh    equ    bufsiz*3/4    ; High XON/XOFF trigger = 3/4 of buffer full.
  225.  
  226. ; external variables used:
  227. ; flags - global flags as per flginfo structure defined in pcdefs
  228. ; trans - global transmission parameters, trinfo struct defined in pcdefs
  229. ; portval - pointer to current portinfo structure (currently either port1
  230. ;    or port2)
  231. ; port1, port2 - portinfo structures for the corresponding ports
  232.  
  233. ; global variables defined in this module:
  234. ; xofsnt, xofrcv - tell whether we saw or sent an xoff.
  235.  
  236. data    segment public 'data'
  237.     extrn    denyflg:word, rdbuf:byte
  238.         extrn   flags:byte, trans:byte, ttyact:byte
  239.         extrn    repflg:byte, diskio:byte, filtst:byte
  240.         extrn    lclexit:word, taklev:byte, takadr:word
  241.         extrn   comand:byte, dmpname:byte, prnhand:word
  242.         extrn   kbdflg:byte, rxtable:byte, mcctab:byte
  243.  
  244. ;------------------------
  245. cpu_clock    db    0
  246. curkey_mode    db    0
  247. keypad_mode    db    0
  248. display_mode    db    0
  249. kanji_7smode    db    0
  250. kanji_7rmode    db    0
  251. kanji_smode    db    0    ; Kanji 1st/2nd byte indicator
  252. kanji_rmode    db    0
  253. kanji_scode    db    0
  254. kanji_rcode    db    0
  255. keyin_dos    db    0
  256. vt100_cursr    db    0    ; cursor attributes
  257. vt100_flags    db    0
  258. vt100_lflag     db      0
  259. vt100_pflag    db    0    ; printer control
  260. vt100_gflag    db    0
  261. ;------------------------
  262. vtgrph_flg    db    0
  263. vttest_flg    db    0
  264. replay_hold    db    0
  265.         db    0    ; adjustment for word boundary
  266. ;------------------------
  267. ;
  268. portval        dw    1
  269. ;
  270. ; previous baud rate for serial port 1
  271. pbaud_1        dw    0FFFFh    ; set unknown baud rate
  272. ;
  273. ; color for Foreground, Background, Highlight and Modeline
  274. ;
  275. def_color    db    07h, 00h, 06h, 07h
  276. scn_color    db    07h, 00h, 06h, 07h
  277. ;------------------------
  278.  
  279. fairness    dw    0
  280.  
  281. KI_len        dw    0
  282. KI_ofs        dw    0
  283.  
  284. KO_len        dw    0
  285. KO_ofs        dw    0
  286.  
  287. pcnet        db    0    ; 2.30 global --> 2.31 local
  288.  
  289. kanjis1        db    0    ; storage for Kanji 1st byte (Keyboard)
  290. kanjis2        db    0
  291. kanjir1        db    0    ; storage for Shift-JIS kanji code
  292. kanjir2        db    0
  293. kanjio1        db    0    ; storage for DEC Kanji code
  294. kanjio2        db    0
  295.  
  296. mdstreg    db    ?        ; modem status register
  297.  
  298. machnam db      'NEC PC-9801 (KEK v1.22  17-APR-1991)$'
  299. erms20  db      cr,lf,'?Warning: System has no disk drives$'
  300. erms40  db      cr,lf,'?Warning: Unrecognized baud rate$'
  301. erms41  db      cr,lf,'?Warning: Cannot open com port$'
  302. erms50  db      cr,lf,'Error reading from device$'
  303. hnd1    db      cr,lf,'Enter a file handle.  Check your DOS manual if you are '
  304.         db      cr,lf,'not certain what value to supply (generally 3).$'
  305. hnd2    db      cr,lf,'Handle: $'
  306. hnderr  db      cr,lf,'Warning: Handle not known.'
  307. deverr  db      cr,lf,'Any routine using the communications port will'
  308.         db      cr,lf,'probably not work.$'
  309. pntmsg    db    'Printer not ready, printing request skipped$'
  310. hndhlp  db      cr,lf,'A one to four digit file handle $'
  311. dev1    db      cr,lf,'Device: $'
  312. devhlp  db      cr,lf,'Name for your systems auxiliary port $'
  313. badbd   db      cr,lf,'Unimplemented baud rate$'
  314. noimp   db      cr,lf,'Command not implemented.$'
  315. hngmsg  db      cr,lf,' The phone should have hungup.',cr,lf,'$'
  316. hnghlp  db      cr,lf,' The modem control lines DTR and RTS for the current'
  317.         db      ' port are forced low (off)'
  318.         db      cr,lf,' to hangup the phone. Normally, Kermit leaves them'
  319.         db      ' high (on) when it exits.'
  320.         db      cr,lf,'$'
  321.  
  322. msmsg1  db      cr,lf,'  Modem is not ready: DSR is off$'
  323. msmsg2  db      cr,lf,'  Modem is ready:     DSR is on$'
  324. msmsg3  db      cr,lf,'  no Carrier Detect:  CD  is off$'
  325. msmsg4  db      cr,lf,'  Carrier Detect:     CD  is on$'
  326. msmsg5  db      cr,lf,'  no Clear To Send:   CTS is off$'
  327. msmsg6  db      cr,lf,'  Clear To Send:      CTS is on$'
  328. vtrname    db    'TERMINALR'        ; a macro name, must be Upper Case
  329. vtrlen    equ    $-vtrname
  330. vtsname    db    'TERMINALS'        ; a macro name, must be Upper Case
  331. vtslen    equ    $-vtsname
  332. prodname db    'PRODUCT'
  333. vtplen    equ    $-prodname
  334. vtmacname dw    vtrname            ; pointer to selected macro name
  335. vtmaclen db    vtrlen
  336. oldsp    dw    0 
  337.  
  338. tmpbuf        db    80 DUP (?)
  339.  
  340. ;playback_hndl    dw    ?
  341. ;playback_fnam    db    80 dup (?)
  342. ;playback_defnam    db    'KERMIT.LOG',0
  343. ;playback_hlp    db    cr,lf,'Filename to playback$'
  344.  
  345. prthnd  dw      0               ; Port handle.
  346. prtnam  db      80 dup (0)    ; Name of auxiliary device
  347. prtdef    db    'AUX',0        ; default device name
  348. prtdev    db    ?        ; device flag (device=1,file=0)
  349. prthld    db    ?        ; hold port
  350. prthlp    db    cr,lf,'specify device/file name (default AUX)$'
  351.  
  352. shkmsg  db      'Not implemented.'
  353. shklen  equ     $-shkmsg
  354. setktab db      0
  355. setkhlp db      0
  356. crlf    db      cr,lf,'$'
  357. delstr  db      BS,BS,'  ',BS,BS,'$'    ; Delete string
  358. fulscr    db    ESCAPE,'[>1h$'
  359. nrmscr    db    ESCAPE,'[>1l$'
  360. delscr    db    ESCAPE,'[2J$'        ; Delete screen
  361. retscr    db    ESCAPE,'[>1h'
  362.     db    ESCAPE,'[25;1H',ESCAPE,'[0J'
  363.     db    cr,'$'
  364.  
  365. ; If delete code moves cursor then BS over code, BS over bad char, space
  366. ; over both to erase from screen, BS twice to restore cursor position.
  367. clrlin  db      cr,'$'                  ; Clear line (just the cr part).
  368. clreol  db      ESCAPE,'[K$'    ; Clear to end of line.
  369. telflg  db      0               ; non-zero if we're a terminal.
  370. argadr  dw      ?               ; address of arg blk from msster.asm
  371. parmsk  db      ?               ; 8/7 bit parity mask, for reception
  372. flowoff db      ?               ; flow-off char, Xoff or null (if no flow)
  373. flowon  db      ?               ; flow-on char, Xon or null
  374. captrtn dw      ?               ; routine to call for captured output
  375. xofsnt  db      0               ; Say if we sent an XOFF.
  376. xofrcv  db      0               ; Say if we received an XOFF.
  377.  
  378. temp    dw      0
  379. temp1   dw      ?               ; Temporary storage.
  380. temp2   dw      ?               ; Temporary storage.
  381.  
  382. ; Entries for choosing communications port
  383. comptab db      9               ; Number of options
  384.         mkeyw   '1',1
  385.         mkeyw   '2',2
  386.     mkeyw    '3',3
  387.         mkeyw   'COM1',1
  388.         mkeyw   'COM2',2
  389.         mkeyw    'COM3',3
  390.     mkeyw    'Device','D'
  391.     mkeyw    'File','D'
  392.         mkeyw   'UB-NETCI','N'
  393.         mkeyw    '   ',0        ; port is not present, for Status
  394.  
  395. vt_ourarg  termarg <>
  396. modem    mdminfo    <mndata,mnst1a,mncmda,0,0,0,0>
  397. timer    tmrinfo    <tmdata,tmcmda,tmsela>
  398.  
  399. ;++ The following structure must be initialized as in MSSKER
  400. ;
  401. port1    prtinfo    <0FFFFh,0,defpar,1,0,defhand,floxon>
  402. port2    prtinfo    <0FFFFh,0,defpar,1,0,defhand,floxon>
  403. portd    prtinfo    <0FFFFh,0,defpar,1,0,defhand,floxon>
  404. portf    prtinfo    <0FFFFh,0,defpar,1,0,defhand,floxon>
  405. portn    prtinfo    <0FFFFh,0,defpar,1,0,defhand,floxon>
  406.  
  407. termtb  db      tttypes                 ; entries for Status, not Set
  408.         mkeyw   'Heath-19',ttheath
  409.         mkeyw   'none',ttgenrc
  410.         mkeyw   'Tek4014',tttek
  411.         mkeyw   'VT102',ttvt100
  412.         mkeyw   'VT52',ttvt52
  413.  
  414. setchtab    db    3
  415.     mkeyw    'EUC',1
  416.     mkeyw    'JIS7',2
  417.     mkeyw    'MS-Kanji',0
  418.  
  419. ; this table is indexed by the baud rate definitions given in
  420. ; pcdefs.  Unsupported baud rates should contain FF.
  421.  
  422. bdtab    db    17
  423.     mkeyw    '45.5',0
  424.     mkeyw    '50',1
  425.     mkeyw    '75',2
  426.     mkeyw    '110',3
  427.     mkeyw    '134.5',4
  428.     mkeyw    '150',5
  429.     mkeyw    '300',6
  430.     mkeyw    '600',7
  431.     mkeyw    '1200',8
  432.     mkeyw    '1800',9
  433.     mkeyw    '2000',10
  434.     mkeyw    '2400',11
  435.     mkeyw    '4800',12
  436.     mkeyw    '9600',13
  437.     mkeyw    '19200',14
  438.     mkeyw    '38400',15
  439.     mkeyw    'Unknown',-1
  440.  
  441. ; Baudrate clock count table for 5/10 MHz CPU
  442.     even
  443. bddat5    label    word            ; AHS 29-MAY-86
  444.     dw    00D30H        ; 45.5 baud
  445.     dw    00C00H        ; 50 baud
  446.     dw    00800H        ; 75 baud
  447.     dw    00574H        ; 110 baud
  448.     dw    00476H        ; 134.5 baud
  449.     dw    00400H        ; 150 baud
  450.     dw    00200H        ; 300 baud
  451.     dw    00100H        ; 600 baud
  452.     dw    00080H        ; 1200 baud
  453.     dw    00055H        ; 1800 baud
  454.     dw    0004DH        ; 2000 baud
  455.     dw    00040H        ; 2400 baud
  456.     dw    00020H        ; 4800 baud
  457.     dw    00010H        ; 9600 baud
  458.     dw    00008H        ; 19200 baud
  459.     dw    00004H        ; 38400 baud (not tested - may not work)
  460.     dw    0FFFFH
  461.     dw    0FFFFH
  462.     dw    0FFFFH
  463.  
  464. ; Baud rate clock count table for 8 MHz CPU
  465.  
  466. bddat8    label    word            ; AHS 29-MAY-86
  467.     dw    0FFFFH        ; 45.5 baud
  468.     dw    0FFFFH        ; 50 baud
  469.     dw    00680H        ; 75 baud
  470.     dw    0FFFFH        ; 110 baud
  471.     dw    0FFFFH        ; 134.5 baud
  472.     dw    00340H        ; 150 baud
  473.     dw    001A0H        ; 300 baud
  474.     dw    000D0H        ; 600 baud
  475.     dw    00068H        ; 1200 baud
  476.     dw    0004EH        ; 1800 baud
  477.     dw    0FFFFH        ; 2000 baud
  478.     dw    00034H        ; 2400 baud
  479.     dw    0001AH        ; 4800 baud
  480.     dw    0000DH        ; 9600 baud
  481.     dw    0FFFFH        ; 19200 baud
  482.     dw    0FFFFH        ; 38400 baud (not tested - may not work)
  483.     dw    0FFFFH
  484.     dw    0FFFFH
  485.     dw    0FFFFH
  486.  
  487. baudlen equ     ($-bddat8)/2     ; number of entries above
  488.  
  489.  
  490. axsave        dw    ?
  491. portinia    dw    0
  492.  
  493. dmphand        dw    ?        ; file handle for dump file
  494.  
  495. oldsera_ofs    dw    ?
  496. oldsera_sgm    dw    ?
  497. oldmska        db    ?
  498. oldmsdat    db    ?
  499.  
  500. ; variables for serial interrupt handler
  501.     even
  502. source    db    bufsiz DUP (?)    ; Buffer for data from port.
  503.     db    2 DUP (?)    ; guard for source.
  504. srcpnt    dw    0        ; Pointer in buffer (DI).
  505. count    dw    0        ; Number of chars in int buffer.
  506. rcvpnt    dw    0        ; Save SI register here.
  507. mdmhand    db    0        ; modem status register, current
  508.  
  509. ; buffer for network
  510.  
  511. xmtbuf    db    NETBUFLEN DUP (0)    ; Buffer for Network xfer.
  512.     db    2 DUP (0)        ; guard
  513. xmtpnt    dw    0
  514. xmtcnt    dw    0
  515. ;
  516.     even
  517.     dw    80 DUP (?)    ; local stack for interrupt processing
  518. mnstk    dw    ?
  519. mnsp    dw    ?        ; remote stack info
  520. mnsseg    dw    ?
  521.  
  522. baud_set    db    0
  523.  
  524. onmsg        db    'off'
  525.         db    'on '
  526. applmsg        db    'normal     '
  527.         db    'application'
  528. colmsg        db    'black  '
  529.         db    'blue   '
  530.         db    'red    '
  531.         db    'magenta'
  532.         db    'green  '
  533.         db    'cyan   '
  534.         db    'yellow '
  535.         db    'white  '
  536. knjmsg        db    'none     '
  537.         db    'DEC-code '
  538.         db    'Shift-JIS'
  539.         db    'JIS-7    '
  540. keyinmsg    db    'BIOS  '
  541.         db    'CON   '
  542.         db    'DOS   '
  543. insrepmsg    db    'Replace'
  544.         db    'Insert '
  545. originmsg    db    'Absolute'
  546.         db    'Relative'
  547. lfnlmsg        db    'Line-feed'
  548.         db    'New-line '
  549. clkmsg        db    '5/10 MHz'
  550.         db    '8 MHz   '
  551. dspmsg        db    'Digital '
  552.         db    'Analogue'
  553.  
  554. vstmsg        db    '<Terminal status>  clock '
  555. vstmsg_clk    db    '        '
  556.         db    '  Diaplay: '
  557. vstmsg_dsp    db    '        '
  558.         db    cr,lf,'  Keyclick: '
  559. vstmsg_key    db    '    '
  560.         db    '  Keyinput: '
  561. vstmsg_keyin    db    '      '
  562.         db    '  Cursorkey: '
  563. vstmsg_curmod    db    '           '
  564.         db    '  Keypad: '
  565. vstmsg_kpdmod    db    '           '
  566.         db    cr,lf,'  Color:  Fore:'
  567. vstmsg_colf    db    '        '
  568.                 db      '  Back:'
  569. vstmsg_colb     db      '        '
  570.         db    '  Highlight:'
  571. vstmsg_colh    db    '        '
  572.                 db      '  Modeline:'
  573. vstmsg_colm     db      '        '
  574.         db    cr,lf,'  Kanji-send: '
  575. vstmsg_sknj    db    '          '
  576.         db    '  Kanji-receive: '
  577. vstmsg_rknj    db    '          '
  578.         db    cr,lf,'  Ins/Rep: '
  579. vstmsg_insrep    db    '       '
  580.         db    '  LF/NL: '
  581. vstmsg_lfnl    db    '         '
  582.         db    '  Orgin: '
  583. vstmsg_origin    db    '        '
  584.         db    '  Wrap: '
  585. vstmsg_autow    db    '    '
  586.         db    cr,lf,'  Cooked-log: '
  587. vstmsg_logcook    db    '    '
  588.         db    '$'
  589.  
  590. data    ends
  591.  
  592. code    segment public 'code'
  593.         extrn   comnd:near, dopar:near, atoi:near, prompt:near
  594.         extrn    isfile:near, strlen:near, strcpy:near
  595.         extrn   sleep:near, msuinit:near, keybd:near
  596.         extrn    kbdlini:near, kbdlend:near
  597.         extrn    ans_keystr:near
  598.     extrn    pntchr:near, pntflsh:near
  599.  
  600.     extrn    vt100:near, vt100_ini:near, vt100_reset:near
  601.     extrn    vt100_save:near, vt100_restore:near, vt100_modlin:near
  602.     extrn    vt100_dump:near, vt100_color:near
  603.     extrn    vt100_rupn:near, vt100_rdnn:near
  604.     extrn    vt100_prnl:near, vt100_prns:near
  605.  
  606.     extrn    tekstat:near
  607.  
  608.      extrn    prn_chk:near        ; in MSYP98.ASM
  609.      extrn    set_modlin:near        ; in MSYP98.ASM
  610.      extrn    gdisp_on:near        ; in MSGP98.ASM
  611.      extrn    set_gcolor:near        ; in MSGP98.ASM
  612.  
  613.      extrn    text_scrn:near        ; in MSZP98.ASM
  614.      extrn    pc98_bell:near        ; in MSZP98.ASM
  615.      extrn    pcwait:near        ; in MSZP98.ASM
  616.      extrn    pcwtst:near        ; in MSZP98.ASM
  617.  
  618.     extrn    tek4014:near, tek4014_ini:near, tek4014_reset:near
  619.     extrn    tek4014_save:near, tek4014_restore:near, tek4014_modlin:near
  620.     extrn    tek4014_color:near
  621.     extrn    sixel_rollup:near, sixel_rolldown:near
  622.  
  623.     extrn    sense_sftkey:near
  624.     extrn    set_keydef:near, reset_keydef:near
  625.     extrn    is_kanji1:near, s2jis:near, jis2s:near
  626.  
  627.         assume  cs:code,ds:data,es:nothing
  628.  
  629. ;-----------------
  630. ; Utility Package
  631. ;-----------------
  632.  
  633. NOUT    PROC    NEAR
  634. ; Copy numeric value from AX to ASCII buffer indicated by DI.
  635. ; DI is updated.
  636.  
  637.     mov    dx,0
  638.     mov    bx,10
  639.     div    bx
  640.     push    dx        ; save remainder digit
  641.     or    ax,ax        ; anything left?
  642.     jz    nout1        ; no, start output phase
  643.     call    nout
  644. nout1:    pop    ax        ; retrieve a digit
  645.     add    al,'0'        ; make it ASCII
  646.     stosb            ; put it in buffer
  647.     ret
  648. NOUT    ENDP
  649.  
  650. ENT_VT    PROC    NEAR
  651. ;@@    call    vt100_restore
  652.     and    vt100_gflag,7Fh        ; mask text screen control
  653.     call    set_gcolor
  654.     call    set_modlin
  655.     call    vt100_modlin
  656.     mov    kanji_rmode,0        ; clear all kanji pending flags
  657.     mov    kanji_smode,0
  658.     ret
  659. ENT_VT    ENDP
  660.  
  661. ENT_TK    PROC    NEAR
  662. ;@@    call    cmblnk
  663. ;@@    call    tek4014_restore
  664.     and    vt100_gflag,7Fh
  665.     cmp    vt100_gflag,4        ; TeK screen ?
  666.     jge    ent_tk_1        ; ge = yes
  667.     mov    vt100_gflag,4
  668. ent_tk_1:
  669.     or    vt100_gflag,80h        ; set text screen cotrol bit
  670.     call    set_gcolor
  671.     call    set_modlin
  672.     call    tek4014_modlin
  673.     mov    kanji_rmode,0
  674.     mov    kanji_smode,0
  675.     ret
  676. ENT_TK    ENDP
  677.  
  678. SET_CUR_COLOR    PROC    NEAR
  679. ;
  680. ; Set the current color.  The color table is given in [si] - [si+3]
  681. ;
  682.     push    ax
  683.     push    di
  684.     mov    di,offset scn_color    ; copy color to current buffer
  685.     mov    ax,[si]            ; fore & back
  686.     mov    [di],ax
  687.     mov    ax,[si+2]        ; highlight & modeline
  688.     mov    [di+2],ax
  689.     pop    di
  690.     pop    ax
  691.     ret
  692. SET_CUR_COLOR    ENDP
  693.  
  694. ;---------------------------------------------------------------------------
  695. ; Clear the input buffer. This throws away all the characters in the
  696. ; serial interrupt buffer.  This is particularly important when
  697. ; talking to servers, since NAKs can accumulate in the buffer.
  698.  
  699. CLRBUF  PROC    NEAR
  700.     cli
  701.     mov    srcpnt,offset source    ; receive circular buffer
  702.     mov    count,0
  703.     sti
  704.     cmp    repflg,0        ; in replay mode ?
  705.     jne    clrbf2            ; ne=yes. do not read any character.
  706. clrbf1:
  707.     call    prtchr            ; empty any intermediate buffers
  708.     jnc    clrbf1            ; got a char, clear again
  709. clrbf2:
  710.     cli
  711.     push    ax
  712.     mov    ax,offset source    ; reset pointers
  713.     mov    rcvpnt,ax
  714.     mov    srcpnt,ax
  715.     mov    count,0
  716.     pop    ax
  717.     sti
  718.         ret
  719. CLRBUF  ENDP
  720.  
  721. ; Clear to the end of the current line.  Returns normally.
  722.  
  723. CLEARL  PROC    NEAR
  724.         push ax
  725.         push dx
  726.         mov ah,prstr
  727.         mov dx,offset clreol
  728.         int dos
  729.         pop dx
  730.         pop ax
  731.         ret
  732. CLEARL  ENDP
  733.  
  734. shomodem    proc    near
  735.     mov     ah,cmeol            ; get a confirm
  736.         call    comnd
  737.         jnc    shomd0
  738.         ret                           ; no confirm
  739. shomd0:
  740. ;
  741.     call    serini            ; activate port to get status
  742.     call    serrst            ; turn off port again
  743. ;
  744.     call    getmodem    ; get modem status in al
  745.     mov    mdstreg,al
  746. ;
  747.     mov    ah,prstr
  748.     mov    dx,offset msmsg1    ; modem not ready msg
  749.     test    mdstreg,moddsr        ; is DSR asserted?
  750.     jz    shomd1            ; z = no
  751.     mov    dx,offset msmsg2    ; say asserted
  752. shomd1:    int    dos
  753.     mov    dx,offset msmsg3    ; CD not asserted msg
  754.     test    mdstreg,modcd        ; CD asserted?
  755.     jz    shomd2            ; z = no
  756.     mov    dx,offset msmsg4    ; say asserted
  757. shomd2:    int    dos
  758.     mov    dx,offset msmsg5    ; CTS asserted msg
  759.     test    mdstreg,modcts        ; CTS asserted?
  760.     jz    shomd3            ; z = no
  761.     mov    dx,offset msmsg6    ; say asserted
  762. shomd3:    int    dos
  763.     clc
  764.     ret
  765. shomodem    endp
  766.  
  767. ;
  768. ; returns modem status in AL. Needs more work.  Current version
  769. ; returns only valid for PORT 1.
  770. ;
  771. getmodem    proc    near
  772.     push    bx
  773.     push    dx
  774.     mov    dx,mnst1a    ; read status of port 1A
  775.     in    al,dx
  776.     and    al,80h        ; set only DR bit
  777.     mov    bl,al        ; save it
  778.     mov    dx,mnrdsa    ; read signal
  779.     in    al,dx
  780.     and    al,60h        ; set CS and CD only
  781.     or    bl,al
  782. ;
  783.     mov    al,0
  784.     test    bl,80h        ; is DSR asserted?
  785.     jz    getmd1        ; z = no
  786.     or    al,moddsr    ; set DSR bit
  787. getmd1:
  788.     test    bl,20h        ; CD asserted?
  789.     jnz    getmd2        ; nz = no
  790.     or    al,modcd    ; set CD bit
  791. getmd2:
  792.     test    bl,40h        ; CTS asserted?
  793. ;@@    jnz    shomd3
  794.     jnz    getmd3        ; @@ [04-Feb-89]
  795.     or    al,modcts    ; set CTS bit
  796. getmd3:
  797.     pop    dx
  798.     pop    bx
  799.     ret
  800. getmodem    endp
  801.  
  802. ; Put the char in AH to the serial port, assumimg the port is active.
  803. ; Returns carry clear if success, else carry set.
  804.  
  805. OUTCHR  PROC    NEAR
  806.     cmp    repflg,0        ; in REPLAY mode?
  807.     je    outch0            ; e=no
  808.     cmp    ah,03h            ; CTRL-C ?
  809.     je    outch0_1        ; e=yes
  810.     xor    replay_hold,1        ; toggle replay_hold flag
  811.     clc
  812.     jmp    outch0_2
  813. outch0_1:
  814.     stc
  815. outch0_2:
  816.     ret
  817. outch0:
  818.     push    cx            ; save regs
  819.     cmp    flowoff,0        ; Are we doing flow control.
  820.     je    outch2
  821.     mov    cx,1500h    ; about 15 sec in 4 millisec interval
  822.         cmp     ah,flowoff      ; sending xoff?
  823.         jne     outch1          ; ne = no
  824.         mov     xofsnt,false    ; supress xon from chkxon buffer routine
  825. outch1: cmp     xofrcv,true     ; Are we being held?
  826.         jne     outch2          ; No - it's OK to go on.
  827.         push    ax
  828.         mov    ax,4        ; 4 millisec wait loop
  829.         call    pcwait
  830.         pop    ax
  831.         loop    outch1          ; held, try for a while
  832.         mov     xofrcv,false    ; timed out, force it off and fall thru.
  833. outch2: push    dx              ; Save register.
  834.     xor    cx,cx
  835.         mov     al,ah           ; Parity routine works on AL.
  836.         call    dopar           ; Set parity appropriately.
  837.                                 ; Begin revised output routine
  838.     mov    ah,al
  839.         mov     temp,ax        ; put data there
  840.     cmp    vt_ourarg.prt,'N'        ; Network port ?
  841.     jne    outch6            ; ne = No.
  842.     pop    dx
  843.     pop    cx
  844.     jmp    outchn
  845. outch6:
  846.     cmp    vt_ourarg.prt,'D'    ; DOS device ?
  847.     jne    outch7        ; ne = no
  848.     jmp    outchd
  849. outch7:
  850.     mov    dx,modem.mdstat
  851. outch3:    in    al,dx
  852.     test    al,txrdy
  853.     jnz    outch4
  854.     loop    outch3
  855.     stc            ; fail to send
  856.     jmp    outch5
  857. outch4:    mov    al,ah
  858.     mov    dx,modem.mddat
  859.     out    dx,al
  860.     clc            ; we have sent it.
  861. outch5:    pop     dx
  862.         pop     cx
  863.     clc
  864.     ret
  865. ;
  866. outchn:
  867.     push    bx
  868.     mov    bx,offset xmtbuf    ; set xfer address
  869.     add    bx,xmtcnt        ; count of chars in buffer
  870.     mov    [bx],ah            ; put char in buffer
  871.     pop    bx
  872.     inc    xmtcnt            ; count of items in this buffer
  873.     cmp    xmtcnt,NETBUFLEN    ; is buffer full now?
  874.     jae    outchn1            ; ae = buffer is full, send it now.
  875.     cmp    ah,trans.seol        ; end of packet?
  876.     je    outchn1            ; e = yes, send buffer.
  877.     cmp    ah,flowon        ; flow control?
  878.     je    outchn1            ; e = yes, always expedite
  879.     cmp    ah,flowoff        ; ditto for flow off
  880.     je    outchn1
  881.     cmp    ttyact,0        ; are we in Connect mode?
  882.     je    outchn2            ; e = no, wait for more before sending
  883. outchn1:
  884.     call    send            ; network send routine
  885.     jc    outchn3            ; c = error
  886. outchn2:
  887.     clc                ; good exit
  888. outchn3:
  889.     ret                ; bad  exit
  890.  
  891. outchd:
  892.         cmp     prthnd,0        ; Got a handle yet?
  893.         jne     outchd3         ; Yup just go on
  894.         call    opnprt          ; Else 'open' the port
  895. outchd3:
  896.     cmp    prtdev,1    ; device ?
  897.     je    outchd5        ; e = yes.
  898.     xor    prthld,1    ; flip-flop
  899.     jmp    outch5
  900. outchd5:
  901.         push    bx
  902.         mov     bx,prthnd       ; port handle
  903.         mov     cx,1            ; one byte to write
  904.         mov     dx,offset temp  ; place where data will be found
  905.         mov     ah,write2       ; dos 2 write to file/device
  906.         int     dos
  907.         pop     bx              ; end of revised routine
  908.         jmp    outch5
  909.  
  910. OUTCHR  ENDP
  911.  
  912. SEND    PROC    NEAR
  913.     push    ax
  914.     push    bx
  915.     push    cx
  916.     push    es
  917. ;
  918.     push    ds
  919.     pop    es            ; ES = DS
  920.     mov    bx,offset xmtbuf    ; xfer start address
  921.     mov    ah,NETCI_WRITE        ; set function
  922.     mov    al,NETCI_PORT        ; set port
  923. ;
  924. send0:
  925.     mov    cx,xmtcnt        ; packet length
  926.     jcxz    send1
  927.     int    NETCI_INT        ; send packet
  928.     cmp    cx,xmtcnt        ; all done ?
  929.     jae    send1            ; e = yes.
  930.     pop    ax
  931.     mov    bx,offset xmtbuf
  932.     add    bx,cx            ; update xfer address
  933.     sub    xmtcnt,cx
  934.     jmp    send0
  935. ;
  936. send1:
  937.     mov    xmtcnt,0
  938.     pop    es
  939.     pop    cx
  940.     pop    bx
  941.     pop    ax
  942.     clc
  943.     ret
  944.  
  945. SEND    ENDP
  946.  
  947. ; This routine blanks the screen.  Returns normally.
  948.  
  949. CMBLNK  PROC    NEAR
  950.         push    ax                 ; save some registers
  951.         push    dx
  952.         mov    ah,prstr
  953.         mov    dx,offset delscr    ; delete screen.
  954.     int    dos
  955.         pop    dx
  956.         pop    ax
  957.         ret
  958. CMBLNK  ENDP
  959.  
  960. ; Homes the cursor.  Returns normally.
  961.  
  962. LOCATE  PROC    NEAR
  963.         mov    dx,0                ; Go to top left corner of screen.
  964.         jmp    poscur
  965. LOCATE  ENDP
  966.  
  967. ; Write a line at the bottom of the screen...
  968. ; the line is passed in dx, terminated by a $.  Returns normally.
  969. putmod  proc    near
  970.         push    dx              ; preserve message
  971.         mov     dx,1800h        ; now address line 24
  972.         call    poscur
  973.         pop     dx              ; get message back
  974.         mov     ah,prstr
  975.         int     dos             ; write it out
  976.         ret                     ; and return
  977. putmod  endp
  978.  
  979. ; clear the mode line written by putmod.  Returns normally.
  980. clrmod  proc    near
  981.         mov     dx,1800h
  982.         call    poscur          ; Go to bottom row.
  983.         call    clearl          ; Clear to end of line.
  984.         ret
  985. clrmod  endp
  986.  
  987. ; Put a help message on the screen.
  988. ; Pass the message in ax, terminated by a null.  Returns normally.
  989. puthlp  proc    near
  990.         push    dx              ; save regs
  991.         push    si
  992.         push    ax              ; preserve this
  993. ;@@    call    cmblnk
  994. ;@@    call    locate
  995.     mov    ah,prstr        ;@@
  996.     mov    dx,offset retscr    ;@@
  997.     int    dos            ;@@
  998.         mov     ah,prstr
  999.         mov     dx,offset crlf
  1000.         int     dos
  1001.         pop     si              ; point to string again
  1002.         cld
  1003. puthl3: lodsb                   ; get a byte
  1004.         cmp     al,0            ; end of string?
  1005.         je      puthl4          ; yes, stop
  1006.         mov     dl,al
  1007.         mov     ah,dconio
  1008.         int     dos             ; else write to screen
  1009.         jmp     puthl3          ; and keep going
  1010. puthl4: mov     ah,prstr
  1011.         mov     dx,offset crlf
  1012.         int     dos
  1013.         pop     si
  1014.         pop     dx
  1015.         ret
  1016. puthlp  endp
  1017.  
  1018. ; Set the baud rate for the current port, based on the value
  1019. ; in the portinfo structure.  Returns normally.
  1020.  
  1021. BAUDST    PROC    NEAR
  1022.     mov    dx,offset bdtab        ; baud rate table, ascii
  1023.     xor    bx,bx            ; help is the table itself
  1024.     mov    ah,cmkey        ; get keyword
  1025.     call    comnd
  1026.     jc    baudst1            ; c = failure
  1027.     push    bx            ; save result
  1028.     mov    ah,cmeol        ; get confirmation
  1029.     call    comnd
  1030.     pop    bx
  1031.     jc    baudst1            ; c = failure
  1032.     mov    si,portval
  1033.     mov    ax,[si].baud        ; remember original value
  1034.     mov    [si].baud,bx        ; set the baud rate
  1035.     call    dobaud            ; use common code
  1036.     clc
  1037. baudst1:ret
  1038. BAUDST    ENDP
  1039. ;
  1040. DOBAUD  PROC    NEAR
  1041.     push    ax
  1042.     push    bx
  1043.     push    dx
  1044. ;
  1045.     mov    axsave,ax
  1046.     mov    bx,portval
  1047.     mov    ax,[bx].baud
  1048.     shl    ax,1
  1049. ;
  1050.     cmp    cpu_clock,CPU_5M_CLOCK
  1051.     je    c5mhz
  1052. c8mhz:
  1053.     mov    bx,offset bddat8
  1054.     jmp    dobd0
  1055. c5mhz:
  1056.     mov    bx,offset bddat5
  1057. dobd0:
  1058.     add    bx,ax
  1059.     cmp    word ptr [bx],0FFFFh
  1060.     jne    dobd1
  1061.     mov    ah,prstr
  1062.     mov    dx,offset badbd
  1063.     int    dos
  1064.     jmp    dobd_ex
  1065. dobd1:
  1066.     mov    ax,[bx]
  1067.     cmp    pbaud_1,ax        ; same as previous baud rate ?
  1068.     jne    dobd2
  1069.     jmp    dobd_ex
  1070. dobd2:
  1071.     call    domode            ; reset RS-232C chip
  1072.     mov    dx,timer.tmcmd
  1073.     mov    al,timer.tmsel
  1074.     out    dx,al
  1075.     mov    ax,[bx]
  1076.     mov    pbaud_1,ax        ; store baud rate
  1077.     mov    dx,timer.tmdat
  1078.     out    dx,al
  1079.     mov    al,ah
  1080.     out    dx,al
  1081.     mov    baud_set,1
  1082. dobd_ex:
  1083.     pop    dx
  1084.         pop    bx
  1085.     pop    ax
  1086.     clc
  1087.         ret                     ; Must be set before starting Kermit.
  1088. DOBAUD  ENDP
  1089.  
  1090. ; Get the current baud rate from the serial card and set it
  1091. ; in the portinfo structure for the current port.  Returns normally.
  1092. ; This is used during initialization.
  1093.  
  1094. GETBAUD PROC    NEAR
  1095.     cmp    flags.comflg,'A'    ; controlable ?
  1096.     jae    gbaud1            ; ae = No. do nothing here.
  1097.     push    bx
  1098.     cmp    baud_set,1    ; Did we already set baud rate?
  1099.     je    gbaud0        ; yes, so just leave
  1100.     mov    bx,portval
  1101.     mov    [bx].baud,B9600
  1102.     mov    baud_set,1
  1103. gbaud0:
  1104.     pop    bx
  1105. gbaud1:
  1106.         ret
  1107. GETBAUD ENDP
  1108.  
  1109. ; Set the mode for the current port.  This is part of the serial
  1110. ; initialization routine.
  1111.  
  1112. DOMODE    PROC    NEAR
  1113.     push    ax
  1114.     push    cx
  1115.     push    dx
  1116. ;
  1117.     mov dx,modem.mdcom    ;send 3 zeros to command port to reset chip
  1118.     mov al,0
  1119.     out dx,al
  1120.     mov al,0
  1121.     out dx,al
  1122.     mov al,0
  1123.     out dx,al
  1124.     mov al,cmode        ;enable mode setting
  1125.     out dx,al
  1126.     mov cx,100        ;allow chip time to reset
  1127. mode1:    loop mode1
  1128.     mov al,mmode        ;mode: 16x rate, 8 data, no parity, 1 stop
  1129.     out dx,al
  1130.     mov cx,100
  1131. mode2:    loop mode2
  1132.     mov al,ccmd        ;RTS & DTR high, RX & TX enabled, reset errors
  1133.     out dx,al
  1134. ;
  1135.     pop    dx
  1136.     pop    cx
  1137.     pop    ax
  1138.     ret
  1139. DOMODE    ENDP
  1140.  
  1141. ; Get Char from    serial port buffer.
  1142. ; returns carry set if no character available at port, otherwise
  1143. ; returns carry clear with char in al, # of chars in buffer in dx.
  1144.  
  1145. PRTCHR  PROC    NEAR
  1146.     cmp    repflg,0        ; in replay mode ?
  1147.     je    prtch0            ; e=no.
  1148.     jmp    prtchf
  1149. prtch0:
  1150.     cmp    vt_ourarg.prt,'D'
  1151.     jne    prtch4
  1152.     jmp    prtchd
  1153. prtch4:
  1154.     call    chkxon
  1155.     cmp    vt_ourarg.prt,'N'
  1156.     jne    prtch3
  1157.     jmp    prtchn
  1158. prtch3:
  1159.     cmp    count,0
  1160.     jnz    prtch2
  1161.     xor    dx,dx        ; No data in buffer
  1162.     xor    al,al
  1163.     stc            ; No data in AL.
  1164.     ret
  1165. prtch2:
  1166.     pushf
  1167.     cli            ; disable interrupts while manipulating pointers
  1168.     push    si        ; save SI (uses in rpack)
  1169.     mov    si,rcvpnt
  1170.     lodsb            ; get a byte
  1171.     cmp    si,offset source + bufsiz    ; bigger than buffer?
  1172.     jb    prtch1        ; no, keep going
  1173.     mov    si,offset source    ; yes wrap around
  1174. prtch1:
  1175.     dec    count
  1176.     mov    rcvpnt,si
  1177.     mov    dx,count
  1178.     pop    si        ; restore SI
  1179.     popf
  1180.     clc            ; we have data in AL
  1181.     ret
  1182. ;
  1183. ;  Read from replay file
  1184. ;
  1185. prtchf:
  1186.     cmp    repflg,1    ; nomral state ?
  1187.     jne    prtchf0        ; ne=no
  1188.     cmp    replay_hold,0    ; holding?
  1189.     je    prtchf1        ; e=no
  1190. prtchf0:
  1191.     xor    dx,dx        ; no char at all.
  1192.     xor    al,al        ; with NUL
  1193.     stc            ; no char is available
  1194.     ret
  1195. prtchf1:
  1196.     push    bx
  1197.     push    cx
  1198.     mov    ah,readf2
  1199.     mov    bx,diskio.handle    ; file handle
  1200.     mov    cx,1            ; read one char
  1201.     mov    dx,offset rdbuf        ; to this buffer
  1202.     int    dos
  1203.     jc    prtchf2            ; c=read failure
  1204.     cmp    ax,cx            ; read the byte?
  1205.     jne    prtchf2            ; ne=no
  1206.     mov    al,rdbuf
  1207.     mov    dx,1
  1208.     clc
  1209.     jmp    prtchf3
  1210. prtchf2:
  1211.     call    pc98_bell        ; notify that we cannot read.
  1212.     mov    repflg,2
  1213.     xor    dx,dx
  1214.     xor    al,al
  1215.     stc
  1216. prtchf3:
  1217.     pop    cx
  1218.     pop    bx
  1219.     ret
  1220. ;
  1221. ;  Read from file/device
  1222. ;
  1223. prtchd:
  1224.     cmp    prthld,0    ; hold ?
  1225.     je    prtchd2        ; e = no
  1226.     stc
  1227.     ret
  1228. prtchd2:
  1229.         push    bx
  1230.         push    cx
  1231.         cmp     prthnd,0        ; Got a handle yet?
  1232.         jne     prtchd0         ; Yup just go on
  1233.         call    opnprt          ; Else 'open' the port
  1234. prtchd0:
  1235.         call    chkxon
  1236.         mov     bx,prthnd
  1237.         mov     al,instat       ; input status command
  1238.         mov     ah,ioctl        ; see note above
  1239.         int     dos
  1240.         jc      prtchd4         ; c = call failed, device not ready
  1241.         or      al,al
  1242.         jz      prtchd4         ; not ready
  1243.         mov     bx,prthnd       ; the file handle
  1244.         mov     ah,readf2       ; read file/device
  1245.         mov     cx,1            ; want just one character
  1246.         mov     dx,offset rdbuf ; where to store it
  1247.         int     dos
  1248.         jnc     prtchd1         ; nc = no error
  1249.         cmp     al,5            ; Error condition
  1250.         je      prt3dx
  1251.         cmp     al,6            ; Error condition
  1252.         je      prt3dx
  1253.         jmp     prtchd4         ; else report no char present
  1254. prtchd1:;;;mov   count,0         ; update count (always 0 for one char reads)
  1255.         mov     dx,0        ; needed to obey rules
  1256.         or      ax,ax           ; reading from end of file?
  1257.         jz      prtchd4         ; z = yes
  1258.         mov     al,rdbuf        ; recover char
  1259. prtchd3:
  1260.         pop     cx
  1261.         pop     bx
  1262.         ret                     ; return success (char is in al)
  1263. prt3dx: mov     ah,prstr
  1264.         mov     dx,offset erms50
  1265.         int     dos
  1266. prtchd4:
  1267.         pop     cx
  1268.         pop     bx
  1269.     xor    dx,dx
  1270.     xor    al,al
  1271.     stc
  1272.     ret
  1273.  
  1274. prtchn:
  1275.     cmp    count,0            ; Data in buffer?
  1276.     je    prtchn0            ; e = No. Get them from port.
  1277.     jmp    prtchn2
  1278. prtchn0:
  1279.     push    ax
  1280.     push    bx
  1281.     push    cx
  1282.     push    es
  1283.     mov    ax,offset source
  1284.     mov    rcvpnt,ax
  1285.     mov    srcpnt,ax
  1286.  ;
  1287.     mov    ah,NETCI_READ
  1288.     mov    al,NETCI_PORT
  1289.     mov    bx,offset source
  1290.     mov    cx,bufsiz
  1291.     push    ds
  1292.     pop    es
  1293.     int    NETCI_INT
  1294.     mov    count,cx
  1295.     add    srcpnt,cx
  1296.     pop    es
  1297.     pop    cx
  1298.     pop    bx
  1299.     pop    ax
  1300.     cmp    count,0
  1301.     jnz    prtchn2
  1302.     xor    dx,dx            ; no data in buffer
  1303.     xor    al,al
  1304.     stc                ; no data in AL.
  1305.     ret
  1306. prtchn2:
  1307.     pushf
  1308.     cli            ; disable interrupts while manipulating pointers
  1309.     push    si        ; save SI
  1310.     mov    si,rcvpnt
  1311.     lodsb            ; get a byte
  1312.     dec    count
  1313.     mov    rcvpnt,si
  1314. ;
  1315. ;    I'm not sure the floowings are necesary or not.
  1316. ;    The handshake should be done at network level.
  1317. ;
  1318. ;    check the data
  1319. ;
  1320. ;@@    push    bx
  1321. ;@@    or    al,al
  1322. ;@@    jz    prtchn5        ; Ignore nulls.
  1323. ;@@    mov    ah,al        ; copy the character in AH
  1324. ;@@    and    ah,parmsk    ; apply parity mask
  1325. ;@@    mov    bx,portval
  1326. ;@@    cmp    [bx].floflg,0    ; Doing flow control?
  1327. ;@@    je    prtchn4        ; Nope.
  1328. ;@@    mov    bx,[bx].flowc    ; Flow control character (BH=XON, BL=XOFF).
  1329. ;@@    cmp    ah,bl        ; Is it an XOFF?
  1330. ;@@    jne    prtchn3        ; Nope, go on.
  1331. ;@@    mov    xofrcv,true    ; Set the flag.
  1332. ;@@    jmp    short prtchn5
  1333. prtchn3:
  1334. ;@@    cmp    ah,bh        ; Get an XON?
  1335. ;@@    jne    prtchn4        ; No, go on.
  1336. ;@@    mov    xofrcv,false    ; Clear our flag.
  1337. ;@@    jmp    short prtchn5
  1338. ;
  1339. prtchn4:
  1340. ;@@    pop    bx
  1341.     mov    dx,count    ; number of characters in buffer
  1342.     pop    si        ; restore SI
  1343.     popf
  1344.     clc            ; we have data in AL.
  1345.     ret
  1346.     
  1347. prtchn5:
  1348. ;@@    pop    bx
  1349. ;@@    popf
  1350. ;@@    jmp    prtchn
  1351.  
  1352. PRTCHR  ENDP
  1353.  
  1354. ; Local routine to see if we have to transmit an xon
  1355. chkxon  proc    near
  1356.         push    bx
  1357.         mov     bx,portval
  1358.         cmp     [bx].floflg,0   ; doing flow control?
  1359.         je      chkxo1          ; no, skip all this
  1360.         cmp     xofsnt,false    ; have we sent an xoff?
  1361.         je      chkxo1          ; no, forget it
  1362.     cmp    count,mntrgh    ; below trigger?
  1363.     jae    chkxo1        ; no, forget it
  1364.         mov     ax,[bx].flowc   ; ah gets xon
  1365.         call    outchr          ; send it
  1366.       nop
  1367.       nop
  1368.       nop                     ; in case it skips
  1369.         mov     xofsnt,false    ; remember we've sent the xon.
  1370. chkxo1: pop     bx              ; restore register
  1371.         ret                     ; and return
  1372. chkxon  endp
  1373.  
  1374. ; IHOSTS - Initialize the host by sending XON, or equivalent, and enter the
  1375. ; cycle of clear input buffer, wait 1 second, test if buffer empty then exit
  1376. ; else repeat cycle. Requires that the port be initialized before hand.
  1377. ; Ihosts is used by the local send-file routine just after initializing
  1378. ; the serial port.
  1379. ; 22 March 1986 [jrd]
  1380.  
  1381. IHOSTS  PROC    NEAR
  1382.         push    ax              ; save the registers
  1383.         push    bx
  1384.         push    cx
  1385.         push    dx
  1386.         mov     bx,portval      ; port indicator
  1387.         mov     ax,[bx].flowc   ; put Go-ahead flow control char in ah
  1388.         or      ah,ah           ; don't send null if flow = none
  1389.         jz      ihosts1         ; z = null
  1390.         call    outchr          ; send it (release Host's output queue)
  1391.          nop                    ; outchr can do skip return
  1392.          nop
  1393.          nop
  1394. ihosts1:call    clrbuf          ; clear out interrupt buffer
  1395.         mov     ax,1            ; sleep for 1 second
  1396. ; NOTE: for systems with a time-of-day clock uncomment the line below
  1397. ; (call sleep) to provide an interval for the host to respond.
  1398.  
  1399.         call    sleep           ; procedure sleep is in msscom.asm
  1400.     cmp    repflg,0    ; in replay mode ?
  1401.     jne    ihosts2        ; ne=yes.
  1402.         call    prtchr          ; check for char at port
  1403.         jnc    ihosts1        ; have a char in al, repeat wait/read cycle
  1404. ihosts2:
  1405.         pop     dx              ; empty buffer. we are done here.
  1406.         pop     cx
  1407.         pop     bx
  1408.         pop     ax
  1409.         ret
  1410. IHOSTS  ENDP
  1411.  
  1412. ; IHOSTR - initialize the remote host for our reception of a file by
  1413. ; sending the flow-on character (XON typically) to release any held
  1414. ; data. Called by receive-file code just after initializing the serial
  1415. ; port.         22 March 1986 [jrd]
  1416. IHOSTR  PROC    NEAR
  1417. ;@@    call    pc98_bell
  1418.         push    ax              ; save regs
  1419.         push    bx
  1420.         push    cx
  1421.         mov     bx,portval      ; port indicator
  1422.         mov     ax,[bx].flowc   ; put Go-ahead flow control char in ah
  1423.         or      ah,ah           ; don't send null if flow = null
  1424.         jz      ihostr1         ; z = null
  1425.         call    outchr          ; send it (release Host's output queue)
  1426. ihostr1:pop     cx
  1427.         pop     bx
  1428.         pop     ax
  1429.         clc
  1430.         ret
  1431. IHOSTR  ENDP
  1432.  
  1433. DTRLOW  PROC    NEAR            ; Global proc to Hangup the Phone by making
  1434.                                 ; DTR and RTS low.
  1435.         mov ah,cmline           ; allow text to be able to display help
  1436.         mov bx,offset rdbuf     ; dummy buffer
  1437.         mov dx,offset hnghlp    ; help message
  1438.         call comnd              ; get a confirm
  1439.         jnc dtrlow1
  1440.         ret
  1441. dtrlow1:
  1442.     call serhng             ; drop DTR and RTS
  1443.         mov ah,prstr            ; give a nice message
  1444.     mov dx,offset hngmsg
  1445.         int dos
  1446.     ret
  1447. DTRLOW  ENDP
  1448.  
  1449. ; Test version for NEC PC-9801 (03-Sep-1988)
  1450. ; Hang up the Phone. Similar to SERRST except it just forces DTR and RTS low
  1451. ; to terminate the connection. 29 March 1986 [jrd]
  1452. ; Calling this twice without intervening calls to serini should be harmless.
  1453. ; Returns normally.
  1454.  
  1455. SERHNG  PROC NEAR
  1456.     mov    dx,modem.mdcom    ; set command port
  1457.     mov    al,chng        ; hangup command
  1458.     out    dx,al
  1459.     xor    cx,cx        ; counts for waiting loop
  1460. serhng1:
  1461.     loop    serhng1
  1462.     mov    pbaud_1,0FFFFh    ; reset previous baud rate
  1463.         ret
  1464. SERHNG  ENDP
  1465.  
  1466. ; Send a break out the current serial port.  Returns normally.
  1467. SENDBR  PROC    NEAR            ; Normal Break
  1468.     cmp    flags.comflg,'N'
  1469.     je    ub_sendbr
  1470.     mov    dx,modem.mdcom    ; set command port
  1471.     mov    al,cbrk+ccmd    ; add break to normal command
  1472.     out    dx,al
  1473.     mov    ax,275        ; wait for 275 milliseconds
  1474.     call    pcwait
  1475.     mov    al,ccmd        ; restore normal command
  1476.     out    dx,al
  1477.         ret
  1478. ub_sendbr:
  1479.         push    ax
  1480.         push    cx
  1481.         mov    ah,NETCI_CNTL    ; control function
  1482.         mov    al,NETCI_PORT
  1483.         mov     cl,NETCI_BRK    ; request break                          [ohl]
  1484.         int     NETCI_INT       ; Net/One command interface int. (6Bh)   [ohl]
  1485.         pop     cx
  1486.         pop     ax
  1487.         ret                     ;  [ohl] ---
  1488.  
  1489. SENDBR  ENDP
  1490.  
  1491. SENDBL  PROC    NEAR            ; Long Break
  1492.     cmp    flags.comflg,'N'
  1493.     je    ub_sendbl
  1494.     mov    dx,modem.mdcom    ; set command port
  1495.     mov    al,cbrk+ccmd    ; add break to normal command
  1496.     out    dx,al
  1497.     mov    ax,1800        ; 1.8 second long break
  1498.     call    pcwait
  1499.     mov    al,ccmd
  1500.     out    dx,al        ; restore normal command
  1501.         ret
  1502. ub_sendbl:
  1503.         push    ax
  1504.         push    cx
  1505.         mov    ah,NETCI_CNTL    ; control function
  1506.         mov    al,NETCI_PORT
  1507.         mov     cl,NETCI_HLD    ; request hold
  1508.         int     NETCI_INT       ; Net/One command interface int. (6Bh)   [ohl]
  1509.         pop     cx
  1510.         pop     ax
  1511.         ret                     ;  [ohl] ---
  1512. SENDBL  ENDP
  1513.  
  1514. ; Position the cursor according to contents of DX:
  1515. ; DH contains row, DL contains column.  Returns normally.
  1516. POSCUR  PROC    NEAR
  1517.     push    di
  1518.     mov    di,offset tmpbuf
  1519.     mov    byte ptr [di],ESCAPE
  1520.     mov    byte ptr [di+1],'['
  1521.     add    di,2
  1522.     mov    al,dh
  1523.     xor    ah,ah
  1524.     inc    ax
  1525.     push    dx
  1526.     call    nout
  1527.     mov    byte ptr [di],';'
  1528.     inc    di
  1529.     pop    dx
  1530.     mov    al,dl
  1531.     xor    ah,ah
  1532.     inc    ax
  1533.     call    nout
  1534.     mov    byte ptr [di],'H'
  1535.     mov    byte ptr [di+1],'$'
  1536.     mov    dx,offset tmpbuf
  1537.     mov    ah,prstr
  1538.     int    dos
  1539.     pop    di
  1540.         ret
  1541. POSCUR  ENDP
  1542.  
  1543. ; Move the cursor to the left margin, then clear to end of line.
  1544. ; Returns normally.
  1545.  
  1546. CTLU    PROC    NEAR
  1547.         mov ah,prstr
  1548.         mov dx,offset clrlin
  1549.         int dos
  1550.         call clearl
  1551.         ret
  1552. CTLU    ENDP
  1553.  
  1554. ; Called only when Kermit exits. Program pointer passed to mssker
  1555. ; in word 'lclexit'.
  1556. ; This is used as a local end routine.
  1557.  
  1558. LCLCLOSE    PROC    NEAR
  1559.     push    ax
  1560.     call    clsprt            ; close device if opened.
  1561.     cmp    pcnet,0            ; network closed ?
  1562.     je    lclclo1            ; e = yes
  1563.     mov    ah,NETCI_CLOSE        ; UB-NETCI close command
  1564.     mov    al,NETCI_PORT
  1565.     int    NETCI_INT
  1566.     mov    pcnet,0
  1567. lclclo1:
  1568.     test    vtgrph_flg,EXITG_BIT
  1569.     jz    lclclo2
  1570.     call    gdisp_on        ; graphic display on
  1571. lclclo2:
  1572.     call    reset_keydef        ; reset key definition table
  1573.     call    kbdlend            ; local reset keyboard routine
  1574.     mov    ah,prstr        ;@@
  1575.     mov    dx,offset nrmscr    ;@@
  1576.     int    dos            ;@@
  1577.     pop    ax
  1578.     ret
  1579. LCLCLOSE    ENDP
  1580.  
  1581. ; Open NETCI port
  1582.  
  1583. chknet    proc    near
  1584.     cmp    pcnet,0            ; netport is closed ?
  1585.     jne    chknetx
  1586.     push    ax
  1587.     push    bx
  1588.     push    cx
  1589.     push    es
  1590. ;
  1591.     push    cs
  1592.     pop    es
  1593.     mov    temp,0
  1594.     mov    bx,offset temp
  1595.     mov    cx,0
  1596.     mov    ah,NETCI_OPEN
  1597.     mov    al,NETCI_PORT
  1598.     int    NETCI_INT
  1599.     mov    lclexit,offset lclclose
  1600.     call    clrbuf
  1601.     mov    xmtcnt,0
  1602.     mov    pcnet,2
  1603. ;
  1604.     pop    es
  1605.     pop    cx
  1606.     pop    bx
  1607.     pop    ax
  1608. chknetx:
  1609.     clc
  1610.     ret
  1611. chknet    endp
  1612.  
  1613. ; Get a file handle for the communications port.  Use DOS call to get the
  1614. ; next available handle.  If it fails, ask user what value to use (there
  1615. ; should be a predefined handle for the port, generally 3).  The open
  1616. ; will fail if the system uses names other than "COM1" or "COM2".
  1617.  
  1618. opnprt    proc    near
  1619.         mov     dx,offset prtnam        ; port name
  1620.         mov     ah,open2                ; open file/device
  1621.         mov     al,2                    ; for reading/writing
  1622.         int     dos
  1623.         jnc     opnpr2                  ; nc = no error so far
  1624.         stc                             ; set carry for failure
  1625.         ret
  1626. opnpr2: mov     prthnd,ax               ; Call succeeded
  1627.     mov    prtdev,1        ; device is assumed
  1628.         mov     ah,ioctl
  1629.         mov     al,00h                  ; get device info
  1630.         xor     dx,dx
  1631.         mov     bx,prthnd               ; port's handle
  1632.         int     dos
  1633.         test    dl,80h            ; is device ?
  1634.         jnz    opnpr3            ; nz = yes.
  1635.     mov    prtdev,0        ; say this is a file
  1636.         ret
  1637. opnpr3:
  1638.         or      dl,20h                  ; set raw mode in device info
  1639.         mov     dh,0
  1640.         mov     ah,ioctl
  1641.         mov     al,01h                  ; set device info
  1642.         int     dos
  1643.         ret                             ; carry clear for success
  1644. opnprt    endp
  1645.  
  1646. clsprt    proc    near
  1647.     cmp    prthnd,0        ; already closed ?
  1648.     je    clsprt1            ; e = yes. Do nothing.
  1649.     push    ax
  1650.     push    bx
  1651.     mov    ah,close2
  1652.     mov    bx,prthnd
  1653.     int    dos
  1654.     mov    prthnd,0
  1655.     pop    bx
  1656.     pop    ax
  1657. clsprt1:
  1658.     ret
  1659. clsprt    endp
  1660.  
  1661. ;
  1662. ; Set the current port.
  1663. ; 
  1664. COMS    PROC    NEAR
  1665.         mov dx,offset comptab   ; the table to examine
  1666.         mov bx,0                ; use keywords as help
  1667.         mov ah,cmkey            ; parse keyword from comptab
  1668.         call comnd
  1669.         jnc  coms0
  1670.         ret            ; no match
  1671. coms0:
  1672.     cmp    bl,'N'        ; Network ?
  1673.     jne    coms1        ; ne = no
  1674.     jmp    comsn        ; Yes, setup for networks
  1675. coms1:
  1676.     cmp    bl,'D'        ; Device ?
  1677.     jne    coms2
  1678.     jmp    comsd        ; Yes, setup for device
  1679. coms2:
  1680.     mov    temp,bx
  1681.         mov    ah,cmeol
  1682.         call    comnd            ; Get a confirm.
  1683.         jnc    coms2_1
  1684.         ret                ;  Didn't get a confirm.
  1685. coms2_1:
  1686.     mov    bx,temp            ; get port number/letter
  1687.     mov    flags.comflg,bl        ; remember port number
  1688.     xor    bh,bh            ; clear high byte
  1689.     mov    bl,flags.comflg        ; get COMx number (1-3)
  1690.     push    bx
  1691.         pop    bx
  1692.     mov    ax,offset port1
  1693.     mov    portval,ax
  1694.     call    inita
  1695.     clc
  1696.     ret
  1697. comsn:
  1698.     mov    temp,bx
  1699.     mov    ah,cmeol
  1700.     call    comnd            ; Get a confirm
  1701.     jnc    comsn0
  1702.     ret                ;  Didn't get a confirm
  1703. comsn0:
  1704.     call    serrst            ; reset serial port
  1705.     call    chknet            ; start network usage
  1706.     cmp    pcnet,0            ; is network alive (non-zero)?
  1707.     jne    comsn4            ; ne = yes
  1708.     stc
  1709.     ret                ; return failure
  1710. comsn4:
  1711.     mov    portval,offset portn    ; set netowrk port data
  1712.     mov    flags.comflg,'N'    ; set the comm port flag.
  1713.     clc                ; return sucess
  1714.     ret
  1715. ;
  1716. comsd:
  1717.  
  1718. ; Set device name. Taken from 'setdmp' in MSSSET.ASM
  1719. ; Puts device name in global string prtnam.
  1720.  
  1721.         mov     dx,offset rdbuf         ; work area
  1722.         mov     rdbuf,0                 ; clear it
  1723.         mov     bx,offset prthlp    ; help message
  1724.         mov     ah,cmword               ; allow paths
  1725.         call    comnd
  1726.         jnc    comsd0
  1727.         ret
  1728. comsd0:
  1729.         mov     ah,cmeol
  1730.         call    comnd
  1731.         jnc    comsd1
  1732.         ret
  1733. comsd1:
  1734.         mov     dx,offset rdbuf         ; assume we will use this text
  1735.         call    strlen                  ; filename given?
  1736.     push    si
  1737.     push    di
  1738.         mov     si,dx                   ; for strcpy
  1739.         cmp     cx,0                    ; length of user's filename
  1740.         jg      comsd2            ; g = filename is given
  1741.         mov     si,offset prtdef    ; no name, use default instead
  1742. comsd2:
  1743.         mov     di,offset prtnam    ; copy to globally available loc
  1744.         call    strcpy
  1745.     pop    di
  1746.     pop    si
  1747.  
  1748.     call    serrst            ; reset serial port
  1749.     call    clsprt            ; close previous device if exists.
  1750.     call    opnprt            ; open device
  1751.     jnc    comsd3
  1752.     stc
  1753.     ret
  1754. comsd3:
  1755.     mov    portval,offset portd    ; set device port data
  1756.     mov    flags.comflg,'D'
  1757.     clc
  1758.     ret
  1759. ;
  1760. COMS    ENDP
  1761.  
  1762. ; Set heath emulation on/off.
  1763.  
  1764.  
  1765. VTSTAT  PROC    NEAR    ; For Status display [jrd]
  1766.     push    ax
  1767.     push    bx
  1768.     push    cx
  1769.     push    dx
  1770.     push    si
  1771.     push    di
  1772.     push    es
  1773. ;
  1774.     push    ds
  1775.     pop    es
  1776.     cld
  1777. ;  CPU clock
  1778.     mov    si,offset clkmsg
  1779.     mov    cx,8
  1780.     cmp    cpu_clock,CPU_5M_CLOCK
  1781.     je    vtstat0
  1782.     add    si,cx
  1783. vtstat0:
  1784.     mov    di,offset vstmsg_clk
  1785.     rep    movsb
  1786. ;  Display
  1787.     mov    si,offset dspmsg
  1788.     mov    cx,8
  1789.     cmp    display_mode,0
  1790.     je    vtstat0_1
  1791.     add    si,cx
  1792. vtstat0_1:
  1793.     mov    di,offset vstmsg_dsp
  1794.     rep    movsb
  1795. ;  Keyclick
  1796.     mov    si,offset onmsg
  1797.     mov    cx,3
  1798.     test    vt100_flags,KEYCLICK_BIT
  1799.     jz    vtstat1
  1800.     add    si,cx
  1801. vtstat1:
  1802.     mov    di,offset vstmsg_key
  1803.     rep    movsb
  1804. ;  Log-cooked
  1805.     mov    si,offset onmsg
  1806.     mov    cx,3
  1807.     test    vt100_lflag,LOGCOOK_BIT
  1808.     jz    vtstat2
  1809.     add    si,cx
  1810. vtstat2:
  1811.     mov    di,offset vstmsg_logcook
  1812.     rep    movsb
  1813. ;  Autowrap
  1814.     mov    si,offset onmsg
  1815.     mov    cx,3
  1816.     test    vt100_flags,AUTOWRAP_BIT
  1817.     jz    vtstat3
  1818.     add    si,cx
  1819. vtstat3:
  1820.     mov    di,offset vstmsg_autow
  1821.     rep    movsb
  1822. ;  Cursor key mode
  1823.     mov    si,offset applmsg
  1824.     mov    cx,11
  1825.     mov    di,offset vstmsg_curmod
  1826.     cmp    curkey_mode,0
  1827.     je    vtstat5
  1828.     add    si,cx
  1829. vtstat5:
  1830.     rep    movsb
  1831. ;  Keypad mode
  1832.     mov    si,offset applmsg
  1833.     mov    cx,11
  1834.     mov    di,offset vstmsg_kpdmod
  1835.     cmp    keypad_mode,0
  1836.     je    vtstat7
  1837.     add    si,cx
  1838. vtstat7:
  1839.     rep    movsb
  1840. ;  Foreground
  1841.     mov    si,offset colmsg
  1842.     mov    di,offset def_color
  1843.     mov    al,[di]
  1844.     mov    ah,0
  1845.     mov    cx,7
  1846.     imul    cl
  1847.     add    si,ax
  1848.     mov    di,offset vstmsg_colf
  1849.     rep    movsb
  1850. ;  Background
  1851.     mov    si,offset colmsg
  1852.     mov    di,offset def_color
  1853.     mov    al,[di+1]
  1854.     mov    ah,0
  1855.     mov    cx,7
  1856.     imul    cl
  1857.     add    si,ax
  1858.     mov    di,offset vstmsg_colb
  1859.     rep    movsb
  1860. ;  Highlight
  1861.     mov    si,offset colmsg
  1862.     mov    di,offset def_color
  1863.     mov    al,[di+2]
  1864.     mov    ah,0
  1865.     mov    cx,7
  1866.     imul    cl
  1867.     add    si,ax
  1868.     mov    di,offset vstmsg_colh
  1869.     rep    movsb
  1870. ;  Modeline
  1871.     mov    si,offset colmsg
  1872.     mov    di,offset def_color
  1873.     mov    al,[di+3]
  1874.     mov    ah,0
  1875.     mov    cx,7
  1876.     imul    cl
  1877.     add    si,ax
  1878.     mov    di,offset vstmsg_colm
  1879.     rep    movsb
  1880. ;  Kanji-code send
  1881.     mov    si,offset knjmsg
  1882.     mov    ah,0
  1883.     mov    al,kanji_scode
  1884.     mov    cx,9
  1885.     imul    cl
  1886.     add    si,ax
  1887.     mov    di,offset vstmsg_sknj
  1888.     rep    movsb
  1889. ;  Kanji-code receive
  1890.     mov    si,offset knjmsg
  1891.     mov    ah,0
  1892.     mov    al,kanji_rcode
  1893.     mov    cx,9
  1894.     imul    cl
  1895.     add    si,ax
  1896.     mov    di,offset vstmsg_rknj
  1897.     rep    movsb
  1898. ;  Keyinput
  1899.     mov    si,offset keyinmsg
  1900.     mov    ah,0
  1901.     mov    al,keyin_dos
  1902.     mov    cx,6
  1903.     imul    cl
  1904.     add    si,ax
  1905.     mov    di,offset vstmsg_keyin
  1906.     rep    movsb
  1907. ;  Insert/Replace
  1908.     mov    si,offset insrepmsg
  1909.     mov    cx,7            ; message length
  1910.     test    vt100_flags,INSERT_BIT
  1911.     jz    vtstat10
  1912.     add    si,cx
  1913. vtstat10:
  1914.     mov    di,offset vstmsg_insrep
  1915.     rep    movsb
  1916. ;  Origin-mode
  1917.     mov    si,offset originmsg
  1918.     mov    cx,8
  1919.     test    vt100_flags,ORIGIN_BIT
  1920.     jz    vtstat11
  1921.     add    si,cx
  1922. vtstat11:
  1923.     mov    di,offset vstmsg_origin
  1924.     rep    movsb
  1925. ;  Line-feed/New-line
  1926.     mov    si,offset lfnlmsg
  1927.     mov    cx,9
  1928.     test    vt100_flags,NEWLINE_BIT
  1929.     jz    vtstat12
  1930.     add    si,cx
  1931. vtstat12:
  1932.     mov    di,offset vstmsg_lfnl
  1933.     rep    movsb
  1934. ;
  1935.     mov    ah,prstr
  1936.     mov    dx,offset vstmsg
  1937.     int    dos
  1938. ;
  1939.     call    tekstat
  1940.     mov    dx,si
  1941.     mov    ah,prstr
  1942.     int    dos
  1943. ;
  1944.     pop    es
  1945.     pop    di
  1946.     pop    si
  1947.     pop    dx
  1948.     pop    cx
  1949.     pop    bx
  1950.     pop    ax
  1951.         ret             ; no emulator status to display
  1952. VTSTAT  ENDP
  1953.  
  1954. ; Save the screen to a buffer and then append buffer to a disk file. [jrd]
  1955. ; Default filename is Kermit.scn; actual file can be a device too. Filename
  1956. ; is determined by mssset and is passed as pointer dmpname.
  1957.  
  1958. DUMPSCR PROC    NEAR    ; Dumps screen contents to a file. Just Beeps here
  1959.  
  1960.     push    ax
  1961.     push    bx
  1962.     push    cx
  1963.     push    dx
  1964.  
  1965.     mov     dmphand,-1              ; preset illegal handle
  1966.     mov     dx,offset dmpname       ; name of disk file, from mssset
  1967.     mov     ax,dx                   ; where isfile wants name ptr
  1968.     call    isfile                  ; what kind of file is this?
  1969.     jc      dmp5                    ; c = no such file, create it
  1970.     test    byte ptr filtst.dta+21,1fh ; file attributes, ok to write?
  1971.     jnz     dmp0                    ; nz = no.
  1972.     mov     al,1                    ; writing
  1973.     mov     ah,open2                ; open existing file
  1974.     int     dos
  1975.     jc      dmp0                    ; c = failure
  1976.     mov     dmphand,ax              ; save file handle
  1977.     mov     bx,ax                   ; need handle here
  1978.     mov     cx,0ffffh               ; setup file pointer
  1979.     mov     dx,-1                   ; and offset
  1980.     mov     al,2                    ; move to eof minus one byte
  1981.     mov     ah,lseek                ; seek the end
  1982.     int     dos
  1983.     jmp     dmp1
  1984.  
  1985. dmp5:    test    filtst.fstat,80h        ; access problem?
  1986.     jnz     dmp0                    ; nz = yes
  1987.     mov     ah,creat2               ; file did not exist
  1988.     mov     cx,20h                  ; attributes, archive bit
  1989.     int     dos
  1990.     mov     dmphand,ax              ; save file handle
  1991.     jnc     dmp1                    ; nc = ok
  1992.  
  1993. dmp0:    call    beep
  1994.     pop     dx
  1995.     pop     cx
  1996.     pop     bx
  1997.     pop     ax
  1998.     clc
  1999.     ret
  2000.  
  2001. dmp1:    mov     ah,ioctl                ; is destination ready for output?
  2002.     mov     al,7                    ; test output status
  2003.     mov     bx,dmphand              ; handle
  2004.     int     dos
  2005.     jc      dmp0                    ; c = error
  2006.     cmp     al,0ffh                 ; ready?
  2007.     jne     dmp0                    ; ne = not ready.
  2008. ;
  2009.     cmp    flags.vtflg,ttvt100
  2010.     je    dmp_v1
  2011.     cmp    flags.vtflg,ttvt52
  2012.     je    dmp_v1
  2013.     call    ent_vt
  2014. dmp_v1:
  2015.     mov     bx,dmphand              ; need file handle
  2016.     call    vt100_dump
  2017. ;
  2018.     mov    bx,offset tmpbuf
  2019.     mov    byte ptr [bx],CTLZ    ; put EOF mark
  2020.     mov    dx,bx
  2021.     mov    bx,dmphand
  2022.     mov    cx,1
  2023.     mov    ah,write2
  2024.     int    dos            ; write EOF
  2025. ;
  2026.     mov     ah,close2               ; close the file now
  2027.     int     dos
  2028. ;
  2029.     pop     dx
  2030.     pop     cx
  2031.     pop     bx
  2032.     pop     ax
  2033.     clc
  2034.     ret
  2035.  
  2036. DUMPSCR ENDP
  2037.  
  2038. ; Initialize variables to values used by this routine.
  2039.  
  2040. lclini:
  2041.     call    detclck        ; determine CPU clock
  2042.     call    pcwtst        ; adjust wait counter
  2043.     mov    prthnd,0    ; No handle yet
  2044.     mov    portval,offset port1    ; default portval
  2045.     mov    pbaud_1,0FFFFh    ; previous baud rate is unknown
  2046.     mov    flags.comflg,1    ; Communication port 1
  2047.     mov    flags.vtflg,ttvt100    ; override default terminal type
  2048.     call    getbaud        ; Put the baud rate in portval [08-Feb-89]
  2049.     mov    curkey_mode,0    ; cursor key is ANSI normal
  2050.     mov    keypad_mode,0    ; keypad is normal
  2051.     mov    vt100_flags,AUTOTEK_BIT    ; set flags
  2052.     mov    vt100_lflag,LOGCOOK_BIT ; log mode is cooked
  2053.     mov    vt100_gflag,0
  2054.     mov    kanji_scode,KNJCODE_DEC    ; DEC kanji code
  2055.     mov    kanji_rcode,KNJCODE_DEC
  2056.     mov    kanji_smode,0    ; 1st character must be Kanji 1st byte.
  2057.     mov    kanji_rmode,0
  2058.     mov    xmtcnt,0        ; clear counter for xfer
  2059.     or    flags.remflg,d8bit    ; display 8-bit
  2060.     call    set_keydef
  2061.     mov    lclexit,offset lclclose    ; set local close routine
  2062.         call    msuinit        ; declare keyboard translator present
  2063.         call    kbdlini        ; keyboard local initialize
  2064.     call    vt100_ini    ; initialize VT100 terminal emulator
  2065.     call    tek4014_ini    ; initialize TEK4014 terminal emulator
  2066.         push    si
  2067.         mov    si,offset def_color
  2068.         call    set_cur_color
  2069.         call    vt100_color    ; setup color index table
  2070.         call    tek4014_color    ; same for Tek4014
  2071.     pop    si
  2072.     mov    ah,prstr        ;@@
  2073.     mov    dx,offset fulscr    ;@@
  2074.     int    dos            ;@@
  2075.     clc
  2076.         ret
  2077.  
  2078. showkey:
  2079.         mov ax,offset shkmsg
  2080.         mov cx,shklen
  2081.         ret
  2082.  
  2083. detclck    proc    near
  2084. ;
  2085. ;  determine CPU clock
  2086. ;
  2087.     mov    cpu_clock,CPU_5M_CLOCK
  2088.     push    ax
  2089.     in    al,042h
  2090.     test    al,0C0h
  2091.     jz    detclck1
  2092.     test    al,020h
  2093.     jz    detclck1
  2094.     mov    cpu_clock,CPU_8M_CLOCK
  2095. detclck1:
  2096.     pop    ax
  2097.     ret
  2098. detclck    endp
  2099.  
  2100. ; serial port interrupt routine.  This is not accessible outside this
  2101. ; module, handles serial port receiver interrupts.
  2102.  
  2103. SERINT    PROC  NEAR
  2104.     push ds            ; save these on remote stack
  2105.     push ax
  2106.     mov ax,seg data        ; get our own data segment
  2107.     mov ds,ax
  2108.     mov mnsp,sp        ; save remote stack information
  2109.     mov mnsseg,ss
  2110.     mov sp,offset mnstk    ; switch to local stack
  2111.     mov ss,ax
  2112.     push es            ; and save remaining registers
  2113.     push bp
  2114.     push di
  2115.     push si
  2116.     push dx
  2117.     push cx
  2118.     push bx
  2119.     mov es,ax
  2120.     call mnproc        ; process the interrupt
  2121.     mov al,icEOI
  2122.           mov dx,intcmda
  2123.     out dx,al
  2124.     pop bx            ; restore registers from stack
  2125.     pop cx
  2126.     pop dx
  2127.     pop si
  2128.     pop di
  2129.     pop bp
  2130.     pop es
  2131.     mov ax,mnsseg        ; switch back to remote stack
  2132.     mov ss,ax
  2133.     mov ax,mnsp
  2134.     mov sp,ax
  2135.     pop ax
  2136.     pop ds
  2137.     iret
  2138.  
  2139. ; handler for serial input
  2140.  
  2141. mnproc:    cld
  2142.     mov di,srcpnt        ; get buffer pointer
  2143.     mov dx,modem.mdstat    ; is data available?
  2144.     in al,dx
  2145.     test al,rxrdy
  2146.     jz mnpro7
  2147.     mov dx,modem.mddat    ; read data
  2148.     in al,dx
  2149.     or al,al
  2150.     jz mnpro7        ; Ignore nulls.
  2151.  
  2152. ; do NOT ignore rubouts, because TEK LOY code use this.
  2153. ;    cmp al,7FH        ; Ignore rubouts, too.
  2154. ;    jz mnpro7
  2155.  
  2156.     mov ah,al
  2157. ;
  2158. ; originally the following was
  2159. ;
  2160. ;    and ah,7fH        ; only consider low-order 7 bits for flow ctl.
  2161. ; do NOT mask 8-th bit for flow control when parity is none.
  2162. ; 
  2163.     and ah,parmsk        ; apply parity mask for flow ctl.
  2164.     mov bp,portval
  2165.     cmp ds:[bp].floflg,0    ; Doing flow control?
  2166.     je mnpro4        ; Nope.
  2167.     mov bx,ds:[bp].flowc    ; Flow control char (BH = XON, BL = XOFF).
  2168.     cmp ah,bl        ; Is it an XOFF?
  2169.     jne mnpro3        ; Nope, go on.
  2170.     mov xofrcv,true        ; Set the flag.
  2171.     jmp short mnpro7
  2172. mnpro3:    cmp ah,bh        ; Get an XON?
  2173.     jne mnpro4        ; No, go on.
  2174.     mov xofrcv,false    ; Clear our flag.
  2175.     jmp mnpro7
  2176. mnpro4:    stosb
  2177.     cmp di,offset source + bufsiz
  2178.     jb mnpro5        ; not past end...
  2179.     mov di,offset source    ; wrap buffer around
  2180. mnpro5:    mov srcpnt,di        ; update ptr
  2181.     inc count
  2182.     cmp ds:[bp].floflg,0    ; Doing flow control?
  2183.     je mnpro7        ; No, just leave.
  2184.     cmp xofsnt,true        ; Have we sent an XOFF?
  2185.     je mnpro7        ; Yes.
  2186.     cmp count,mntrgh    ; Past the high trigger point?
  2187.     jbe mnpro7        ; No, we're within our limit.
  2188.     mov ah,bl        ; Get the XOFF.
  2189.     call outchr        ; Send it.
  2190.      nop            ;   ignore failure.
  2191.      nop
  2192.      nop
  2193.     mov xofsnt,true        ; Remember we sent it.
  2194. mnpro7:    ret
  2195.  
  2196. SERINT    ENDP
  2197.  
  2198. ; Initialization for using serial port.  Returns normally.
  2199.  
  2200. SERINI  PROC    NEAR
  2201.     cmp    flags.comflg,'A'    ;@@@@@
  2202.     jae    serin1            ;@@@@@
  2203.     call    inita
  2204.  
  2205. serin0:;;;;     call clrbuf     ; Clear input buffer.
  2206. ;;        push    bx
  2207. ;;        mov     bx,portval      ; get port
  2208. ;;        mov     parmsk,0ffh     ; parity mask, assume parity is None
  2209. ;;        cmp     [bx].parflg,parnon ; is it None?
  2210. ;;        je      serin1          ; e = yes
  2211. ;;        mov     parmsk,07fh     ; no, pass lower 7 bits as data
  2212. ;;serin1: mov     bx,[bx].flowc   ; get flow control chars
  2213. ;;        mov     flowoff,bl      ; xoff or null
  2214. ;;        mov     flowon,bh       ; xon or null
  2215. ;;        pop     bx
  2216. serin1:
  2217.     clc            ; always success ! true ?!
  2218.         ret                     ; We're done.
  2219. SERINI  ENDP
  2220.  
  2221. ; Reset the serial port.  This is the opposite of serini.  Calling
  2222. ; this twice without intervening calls to serini should be harmless.
  2223. ; Returns normally.
  2224.  
  2225. SERRST  PROC    NEAR
  2226.     cmp portinia,0        ; Did we reset port already?
  2227.     je rsta0        ; Yes, so just leave.
  2228.     push es
  2229.     cli            ; Disable interrupts
  2230.     xor ax,ax        ; Address low memory
  2231.     mov es,ax
  2232.     mov ax,oldsera_ofs    ; Restore interrupt vector
  2233.     mov es:[4*icsvcta],ax
  2234.     mov ax,oldsera_sgm
  2235.     mov es:[4*icsvcta+2],ax
  2236.     mov dx,intmska        ; restore old master controller mask
  2237.     mov al,oldmska
  2238.     out dx,al
  2239.     mov dx,mnmska        ; disable serial interrupts at port
  2240. ;    mov al,txmsk+rxmsk+tbemsk
  2241.     mov al,oldmsdat
  2242.     out dx,al
  2243.     mov portinia,0        ; Remember port has been reset
  2244.     sti            ; Allow interrupts
  2245.     pop es
  2246. rsta0:
  2247.     clc
  2248.     ret
  2249. SERRST  ENDP
  2250.  
  2251. ; Local routine to initialize the standard serial port
  2252.  
  2253. INITA    PROC    NEAR
  2254.     cmp    portinia,1    ; Did we initialize port already ?
  2255.     je    inita0        ; Yes, so just leave.
  2256. ;
  2257.     cli            ; Disable interrupts
  2258.     push    ax
  2259.     push    dx
  2260.     push    es
  2261. ;
  2262.     mov    ax,offset port1
  2263.     mov    portval,ax
  2264.     xor    ax,ax
  2265.     mov    es,ax
  2266.     mov    ax,es:[4*icsvcta]    ; save interrupt vector for port1
  2267.     mov    oldsera_ofs,ax
  2268.     mov    ax,es:[4*icsvcta+2]
  2269.     mov    oldsera_sgm,ax
  2270.     mov    ax,offset serint    ; pointer to our routine
  2271.     mov    es:[4*icsvcta],ax    ; set interrupt routine offset
  2272.     mov    es:[4*icsvcta+2],cs    ;  and segment
  2273.     mov    dx,intmska
  2274.     in    al,dx
  2275.     mov    oldmska,al        ; save old master controller mask
  2276. ;
  2277.     and    al,not icsmska        ; enable serial interrupt at master
  2278.     out    dx,al
  2279.     mov    dx,mnmska
  2280.     in    al,dx
  2281.     mov    oldmsdat,al
  2282.     and    al,0f8h
  2283.     or    al,rxmsk
  2284.     out    dx,al
  2285.     mov    modem.mddat,mndata
  2286.     mov    modem.mdstat,mnst1a
  2287.     mov    modem.mdcom,mncmda
  2288.     mov    timer.tmdat,tmdata
  2289.     mov    timer.tmcmd,tmcmda
  2290.     mov    timer.tmsel,tmsela
  2291.     call    dobaud
  2292.     mov    portinia,1
  2293.     call    clrbuf
  2294. ;
  2295.     pop    es
  2296.     pop    dx
  2297.     pop    ax
  2298.     sti
  2299. inita0:    ret
  2300. INITA    ENDP
  2301.  
  2302. ;
  2303. ; Produce a short beep.  The PC DOS bell is long enough to cause a loss
  2304. ; of data at the port.  Returns normally.
  2305.  
  2306. BEEP    PROC    NEAR
  2307.         mov dl,bell
  2308.         mov ah,dconio
  2309.         int dos
  2310.         ret
  2311. BEEP    ENDP
  2312. ;
  2313.  
  2314.  
  2315. ; Terminal emulator.
  2316. ;
  2317. term    proc    near
  2318.     mov    oldsp,sp        ; remember stack for i/o failure,
  2319.     mov    prthld,0        ; clear port hold flag at the beginning
  2320.     mov    replay_hold,0
  2321.     mov    bx,portval
  2322.     mov    bx,[bx].flowc        ; get flow control character
  2323.     mov    flowoff,bl
  2324.     mov    flowon,bh
  2325.     or    vt100_flags,AUTOTEK_BIT
  2326.     test    denyflg,tekxflg
  2327.     jz    term_01
  2328.     and    vt100_flags,(not AUTOTEK_BIT)
  2329. term_01:
  2330.     and    vt100_lflag,(not LOGENAB_BIT)
  2331.     test    flags.capflg,logses    ; session logging enabled?
  2332.     jz    term_02            ; z = no.
  2333.     or    vt100_lflag,LOGENAB_BIT
  2334. term_02:
  2335.     call    vt100_restore
  2336.     call    tek4014_restore
  2337.     mov    fairness,0
  2338.     mov    kanji_smode,0        ; clear Kanji pending flag
  2339.     mov    kanji_rmode,0
  2340.     mov    kanji_7smode,0
  2341.     mov    kanji_7rmode,0
  2342.         mov     argadr,ax               ; save argument ptr
  2343.         mov     si,ax                   ; this is source
  2344.         mov     di,offset vt_ourarg        ; place to store arguments
  2345.         mov     ax,ds
  2346.         mov     es,ax                   ; address destination segment
  2347.         mov     cx,size termarg
  2348.         cld
  2349.         rep     movsb                   ; copy into our arg blk
  2350. ;@@    and    vt_ourarg.flgs,not (prtscr) ; no screen printing at startup
  2351. ;@@    mov    vt100_pflag,0
  2352.         mov     ax,vt_ourarg.captr
  2353.         mov     captrtn,ax              ; buffer capture routine
  2354.     test    vt_ourarg.flgs,modoff    ; mode line off?
  2355.     jnz    term_1
  2356.     call    set_modlin        ; setup mode line
  2357. term_1:
  2358.         mov     parmsk,0ffh             ; parity mask, assume parity = None
  2359.         cmp     vt_ourarg.parity,parnon    ; is parity None?
  2360.         je      term_2            ; e = yes, keep all 8 bits
  2361.         mov     parmsk,07fh             ; else keep lower 7 bits
  2362. term_2:
  2363.     mov    ax,KI_code
  2364.     call    ans_keystr
  2365.     mov    KI_len,cx
  2366.     mov    KI_ofs,bx
  2367.     mov    ax,KO_code
  2368.     call    ans_keystr
  2369.     mov    KO_len,cx
  2370.     mov    KO_ofs,bx
  2371. ;
  2372.     cmp    flags.vtflg,ttvt100    ; vt100 emulation ?
  2373.     je    term_vt            ; e = yes.
  2374.     cmp    flags.vtflg,ttvt52    ; vt52 emulation ?
  2375.     je    term_vt            ; e = yes.
  2376.     cmp    flags.vtflg,tttek    ; Tek4014 emulation ?
  2377.     je    term_tk            ; e = yes.
  2378.     jmp    term0            ; non supported terminal
  2379. ;
  2380. ;  vt100/vt52 emulation
  2381. term_vt:
  2382.     call    ent_vt
  2383.     jmp    term0
  2384. ;
  2385. ;  tek4014 emulation
  2386. term_tk:
  2387.     call    ent_tk
  2388. ;
  2389. term0:
  2390. ;    test    vt100_flags,LOOPTEST_BIT
  2391. ;    je    term1
  2392. ;    jmp    term_tst1
  2393.  
  2394. term1:  call    portchr         ; get char from port, apply parity mask
  2395.         jc    short term2    ; c = no char, go on
  2396.         call    outtty          ; display and capture char
  2397.     inc    fairness
  2398.     cmp    fairness,100
  2399.     jb    term1        ; do quick loop back for more
  2400. term2:    mov    fairness,0
  2401.     call    pntflsh        ; flush printer buffer
  2402.     jnc    term2a        ; nc = success
  2403.     call    pntdead        ; call bad printer notifier
  2404. term2a:    call    keybd           ; keyboard translator to read and send text
  2405.         jnc     term1           ; nc = do not exit Connect mode
  2406.  
  2407. quit:    call    pntflsh        ; flush printer buffer
  2408.     cmp    flags.vtflg,ttgenrc    ; no emulation ?
  2409.     je    term3
  2410.     call    vt100_save
  2411.     call    tek4014_save
  2412. term3:    mov    al,1
  2413.     call    text_scrn    ; ON the text screen
  2414.     xor    al,al
  2415.     mov    ah,prstr
  2416.         mov    dx,offset retscr
  2417.         int    dos
  2418.     ret
  2419.  
  2420. ;term_tst1:
  2421. ;    mov    ax,3D00h    ; open file (read only)
  2422. ;    mov    dx,offset playback_fnam
  2423. ;    int    dos
  2424. ;    jc    term_tstz    ; if error, then normal operation
  2425. ;    mov    playback_hndl,ax
  2426. ;term_tst2:
  2427. ;@@    call    portchr
  2428. ;@@    jnc    short term_tst3
  2429. ;@@    call    outtty
  2430. ;@@    jmp    term_tst2
  2431. ;term_tst3:
  2432. ;    mov    ah,3Fh        ; read file/device
  2433. ;    mov    dx,offset tmpbuf
  2434. ;    mov    bx,playback_hndl
  2435. ;@@    mov    cx,8
  2436. ;    mov    cx,72        ;@@
  2437. ;    int    dos
  2438. ;    jc    term_tstx
  2439. ;    mov    cx,ax
  2440. ;    jcxz    term_tstx
  2441. ;    mov    si,offset tmpbuf
  2442. ;term_tst4:
  2443. ;    push    cx
  2444. ;    push    si
  2445. ;@@    mov    ah,[si]
  2446. ;@@    call    outchr
  2447. ;@@     nop
  2448. ;@@     nop
  2449. ;@@     nop
  2450. ;    mov    al,[si]        ;@@
  2451. ;    call    outtty        ;@@
  2452. ;    pop    si
  2453. ;    pop    cx
  2454. ;    inc    si
  2455. ;
  2456. ;  check the keyboard by using direct console i/o
  2457. ;  Any key can be used for toggle of screen output.
  2458. ;
  2459. ;    push    dx
  2460. ;    mov    ah,dconio    ; direct console i/o
  2461. ;    mov    dl,0ffh        ; read
  2462. ;    int    dos
  2463. ;    jz    term_tst5
  2464. ;term_tst6:
  2465. ;    mov    ah,dconio
  2466. ;    mov    dl,0ffh
  2467. ;    int    dos
  2468. ;    jz    term_tst6
  2469. ;    cmp    al,CR
  2470. ;    jne    term_tst5
  2471. ;    pop    dx
  2472. ;    jmp    term_tstx
  2473. ;term_tst5:
  2474. ;    pop    dx
  2475. ;
  2476. ;    loop    term_tst4
  2477. ;    jmp    term_tst2
  2478. ;term_tstx:
  2479. ;    mov    ah,3Eh
  2480. ;    mov    bx,playback_hndl
  2481. ;    int    dos
  2482. ;term_tstz:
  2483. ;    and    vt100_flags,NOT LOOPTEST_BIT
  2484. ;    clc
  2485. ;    jmp    term1
  2486.  
  2487. term    endp
  2488.  
  2489. ;; keyboard translator action routines, system dependent, called from msugen.
  2490. ; These are invoked by a jump instruction. Return carry clear for normal
  2491. ; processing, return carry set exit Connect mode (kbdflg has transfer char).
  2492.  
  2493. ; kanji_shiftin sends designation codes for G0 to JIS-C6226.
  2494. ; kanji_shiftout sends designation codes for G0 to JIS-roman.
  2495. ; These routines are called in chrout when JIS-7 is specified.
  2496.  
  2497. kanji_shiftin    proc    near
  2498.     push    ax        ; save ax
  2499.     push    cx
  2500.     push    si
  2501.     mov    cx,KI_len
  2502.     jcxz    kanji_shiftin2
  2503.     mov    si,KI_ofs
  2504. kanji_shiftin1:
  2505.     mov    al,[si]
  2506.     push    si        ; save si and cx.
  2507.     push    cx        ;   these are broken when local echo is on
  2508.     call    outprt
  2509.     pop    cx
  2510.     pop    si
  2511.     inc    si
  2512.     loop    kanji_shiftin1
  2513. kanji_shiftin2:
  2514.     mov    kanji_7smode,1
  2515.     pop    si
  2516.     pop    cx
  2517.     pop    ax
  2518.     ret
  2519. kanji_shiftin    endp
  2520.  
  2521. kanji_shiftout    proc    near
  2522.     push    ax        ; save ax
  2523.     push    cx
  2524.     push    si
  2525.     mov    cx,KO_len
  2526.     jcxz    kanji_shiftout2
  2527.     mov    si,KO_ofs
  2528. kanji_shiftout1:
  2529.     mov    al,[si]
  2530.     push    si        ; save si and cx.
  2531.     push    cx        ;   these are broken when local echo is on
  2532.     call    outprt
  2533.     pop    cx
  2534.     pop    si
  2535.     inc    si
  2536.     loop    kanji_shiftout1
  2537. kanji_shiftout2:
  2538.     mov    kanji_7smode,0
  2539.     pop    si
  2540.     pop    cx
  2541.     pop    ax
  2542.     ret
  2543. kanji_shiftout    endp
  2544.  
  2545. ; chrout is called from KEYBD after key definition translation.
  2546. ; the character is in AL.
  2547.  
  2548. chrout:
  2549.     cmp    kanji_scode,KNJCODE_NONE    ; if kanji is not used,
  2550.     je    chroutx2            ;   no translation
  2551.     cmp    kanji_scode,KNJCODE_SJIS    ; if shift-JIS is used,
  2552.     je    chroutx2            ;   no translation
  2553.     cmp    kanji_smode,0        ; 1st byte ?
  2554.     je    chrout_1        ; e = yes,
  2555.     jmp    chrout_knj2
  2556. chrout_1:
  2557.     call    is_kanji1        ; Kanji code 1st byte ?
  2558.     jnc    chroutx            ; nc = no. ASCII character
  2559.     mov    kanjis1,al
  2560.     mov    kanji_smode,1
  2561.     jmp    chroutxx
  2562. chroutx:
  2563.     cmp    kanji_scode,KNJCODE_JIS7    ; JIS-7 used ?
  2564.     jne    chroutx2        ; ne = no
  2565.     cmp    kanji_7smode,0        ; roman-mode ?
  2566.     je    chroutx2        ; e = yes.
  2567.     cmp    al,DEL            ; BS and DEL can be used in Kanji mode
  2568.     je    chroutx2
  2569.     cmp    al,BS
  2570.     je    chroutx2
  2571.     call    kanji_shiftout
  2572. chroutx2:
  2573.     test    vt100_flags,NEWLINE_BIT    ; newline mode ?
  2574.     jz    chroutx1        ; z = no
  2575.     cmp    al,0Dh            ; CR ?
  2576.     jne    chroutx1        ; ne = no
  2577.     call    outprt            ; send it
  2578.     mov    al,0Ah            ; send LF
  2579. chroutx1:
  2580.     call    outprt                  ; put char in al to serial port
  2581.     mov    kanji_smode,0
  2582. chroutxx:
  2583.         clc                             ; stay in Connect mode
  2584.         ret
  2585.  
  2586. chrout_knj2:
  2587.     mov    ah,al
  2588.     mov    al,kanjis1
  2589.     call    s2jis
  2590.     cmp    kanji_scode,KNJCODE_JIS7    ; JIS-7 used ?
  2591.     je    chrout_knj21            ; e = yes.
  2592.     or    ax,8080h        ; convert to DEC code
  2593.     jmp    chrout_knj22
  2594. chrout_knj21:
  2595.     cmp    kanji_7smode,0        ; roman-mode ?
  2596.     jne    chrout_knj22        ; ne = no.
  2597.     call    kanji_shiftin
  2598. chrout_knj22:
  2599.     mov    kanjis1,ah
  2600.     mov    ah,0
  2601.     call    outprt
  2602.     mov    al,kanjis1
  2603.     jmp    chroutx1
  2604.  
  2605. trnprs:    push    ax            ; toggle Copy screen to printer
  2606.     test    vt100_pflag,(AUTOPRINT_BIT+PRINTCTRL_BIT)
  2607.                     ; are we currently printing?
  2608.     jz    trnpr0            ; z = no, check the printer status
  2609.     and    vt100_pflag,(not (AUTOPRINT_BIT+PRINTCTRL_BIT))
  2610.                     ; clear printer flag
  2611.     jmp    trnpr1            ; and going off
  2612. trnpr0:
  2613.     push    bx
  2614.     mov    bx,prnhand        ; file handle for system printer
  2615.     mov    ah,ioctl
  2616.     mov    al,7            ; get output status of printer
  2617.     int    dos
  2618.     pop    bx
  2619.     jc    trnpr1            ; c = printer not ready
  2620.     cmp    al,0ffh            ; Ready status
  2621.     jne    trnpr3            ; ne = not-Ready    
  2622.     or    vt100_pflag,AUTOPRINT_BIT    ; set the autoprint flag
  2623. trnpr1:    call    set_modlin
  2624.     call    vt100_modlin
  2625. trnpr3:    pop    ax
  2626.     clc                ; return carry clear (don't quit)
  2627.     ret
  2628.  
  2629. prtscn:    call    vt100_prns
  2630.     clc
  2631.     ret
  2632.  
  2633. klogon    proc    near            ; resume logging (if any)
  2634.     test    flags.capflg,logses    ; session logging enabled?
  2635.     jz    klogn            ; z = no, forget it
  2636.         or      vt_ourarg.flgs,capt        ; turn on capture flag
  2637. klogn:  clc
  2638.         ret
  2639. klogon  endp
  2640.  
  2641. klogof  proc    near                    ; suspend logging (if any)
  2642.         and     argadr.flgs,not capt    ; stop capturing
  2643. klogo:  clc
  2644.         ret
  2645. klogof  endp
  2646.  
  2647. uparrw:    mov    al,'A'
  2648.     jmp    short comarr
  2649. dnarrw:    mov    al,'B'
  2650.     jmp    short comarr
  2651. rtarrw:    mov    al,'C'
  2652.     jmp    short comarr
  2653. lfarrw:    mov    al,'D'
  2654. comarr:    push    ax
  2655.     mov    al,ESCAPE        ; [06-July-1990]
  2656.     call    outprt            ; [06-July-1990]
  2657.     cmp    flags.vtflg,ttvt52
  2658.     je    comar2
  2659.     mov    al,'['            ; [06-July-1990]
  2660.     cmp    curkey_mode,0
  2661.     je    comar1
  2662.     mov    al,'O'            ; [06-July-1990]
  2663. comar1:    call    outprt            ; [06-July-1990]
  2664. comar2:
  2665.     pop    ax
  2666.     call    outprt            ; [06-July-1990]
  2667.     clc
  2668.     ret
  2669.  
  2670. pf1:    mov    al,'P'
  2671.     jmp    short compf
  2672. pf2:    mov    al,'Q'
  2673.     jmp    short compf
  2674. pf3:    mov    al,'R'
  2675.     jmp    short compf
  2676. pf4:    mov    al,'S'
  2677. compf:    push    ax
  2678.     mov    al,ESCAPE        ; [06-July-1990]
  2679.     call    outprt            ; [06-July-1990]
  2680.     cmp    flags.vtflg,ttvt52
  2681.     je    compf1
  2682.     mov    al,'O'
  2683.     call    outprt            ; [06-July-1990]
  2684. compf1:
  2685.     pop    ax
  2686.     call    outprt            ; [06-July-1990]
  2687.     clc
  2688.     ret
  2689.  
  2690. kp0:    mov    al,'p'
  2691.     jmp    short comkp
  2692. kp1:    mov    al,'q'
  2693.     jmp    short comkp
  2694. kp2:    mov    al,'r'
  2695.     jmp    short comkp
  2696. kp3:    mov    al,'s'
  2697.     jmp    short comkp
  2698. kp4:    mov    al,'t'
  2699.     jmp    short comkp
  2700. kp5:    mov    al,'u'
  2701.     jmp    short comkp
  2702. kp6:    mov    al,'v'
  2703.     jmp    short comkp
  2704. kp7:    mov    al,'w'
  2705.     jmp    short comkp
  2706. kp8:    mov    al,'x'
  2707.     jmp    short comkp
  2708. kp9:    mov    al,'y'
  2709.     jmp    short comkp
  2710. kpmins:    mov    al,'m'
  2711.     jmp    short comkp
  2712. kpcoma:    mov    al,'l'
  2713.     jmp    short comkp
  2714. kpentr:    mov    al,'M'
  2715.     jmp    short comkp
  2716. kpdot:    mov    al,'n'
  2717.     jmp    short comkp
  2718. comkp:    cmp    keypad_mode,0
  2719.     je    comkp1
  2720.     push    ax
  2721.     mov    al,ESCAPE        ; [06-July-1990]
  2722.     call    outprt            ; [06-July-1990]
  2723.     mov    al,'O'            ; [06-July-1990]
  2724.     cmp    flags.vtflg,ttvt52
  2725.     jne    comkp0
  2726.     mov    al,'?'            ; [06-July-1990]
  2727. comkp0:
  2728.     call    outprt            ; [06-July-1990]
  2729.     pop    ax
  2730.     jmp    short comkp2
  2731. comkp1:    sub    al,40h
  2732. comkp2:
  2733.     call    outprt            ; [06-July-1990]
  2734.     clc
  2735.     ret
  2736.  
  2737. decf6:
  2738. decf7:
  2739. decf8:
  2740. decf9:
  2741. decf10:
  2742. decf11:
  2743. decf12:
  2744. decf13:
  2745. decf14:
  2746. dechelp:
  2747. decdo:
  2748. decf17:
  2749. decf18:
  2750. decf19:
  2751. decf20:
  2752.     jmp    comdec1
  2753. decfind:
  2754.     mov    ah,'1'
  2755.     jmp    comdec
  2756. decinsert:
  2757.     mov    ah,'2'
  2758.     jmp    comdec
  2759. decremove:
  2760.     mov    ah,'3'
  2761.     jmp    comdec
  2762. decselect:
  2763.     mov    ah,'4'
  2764.     jmp    comdec
  2765. decprev:
  2766.     mov    ah,'5'
  2767.     jmp    comdec
  2768. decnext:
  2769.     mov    ah,'6'
  2770. comdec:
  2771.     push    ax
  2772.     mov    ah,ESCAPE
  2773.     call    outchr
  2774.     mov    ah,'['
  2775.     call    outchr
  2776.     pop    ax
  2777.     call    outchr
  2778.     mov    ah,'~'
  2779.     call    outchr
  2780. comdec1:
  2781.     clc
  2782.     ret
  2783.  
  2784. snull:  mov     ah,0                    ; send a null
  2785.         call    outchr                  ; send without echo or logging
  2786.          nop
  2787.          nop
  2788.          nop
  2789.         clc
  2790.         ret
  2791.  
  2792. keyinchg:
  2793.     xor    keyin_dos,1
  2794.     clc
  2795.     ret
  2796.  
  2797. ; change terminal emulator
  2798. ;
  2799. vtchg:
  2800.     cmp    flags.vtflg,ttvt100    ; vt100 emulation mode?
  2801.     jne    vtchg_nvt100
  2802.     call    vt100_save
  2803.     jmp    vtchg1
  2804. vtchg_nvt100:
  2805.     cmp    flags.vtflg,tttek    ; tek emulation mode?
  2806.     jne    vtchg_ntek
  2807.     call    tek4014_save
  2808.     jmp    vtchg1
  2809. vtchg_ntek:
  2810. vtchg1:
  2811.     inc    flags.vtflg
  2812.     cmp    flags.vtflg,TTTYPES
  2813.     jb    vtchg2
  2814.     mov    flags.vtflg,ttgenrc
  2815.     jmp    vtchg3
  2816. vtchg2:
  2817.     cmp    flags.vtflg,ttgenrc
  2818.     jne    vtchg21
  2819.     jmp    vtchg3
  2820. vtchg21:
  2821.     cmp    flags.vtflg,ttvt100
  2822.     jne    vtchg22
  2823.     call    ent_vt
  2824.     jmp    vtchg3
  2825. vtchg22:
  2826.     cmp    flags.vtflg,tttek
  2827.     jne    vtchg23
  2828.     call    ent_tk
  2829.     jmp    vtchg3
  2830. vtchg23:
  2831.     call    set_modlin
  2832.     call    vt100_modlin
  2833.     jmp    vtchg1
  2834. vtchg3:
  2835.     clc            ; stay in connect mode
  2836.     ret
  2837. ;
  2838. ; reset terminal
  2839. vtreset:
  2840.     cmp    flags.vtflg,ttvt100
  2841.     jne    vtreset1
  2842.     call    vt100_reset
  2843.     jmp    vtresetx
  2844. vtreset1:
  2845.     cmp    flags.vtflg,tttek
  2846.     jne    vtreset2
  2847.     call    tek4014_reset
  2848.     jmp    vtresetx
  2849. vtreset2:
  2850. vtresetx:
  2851.     clc
  2852.     ret
  2853.  
  2854. upone:
  2855.     push    ax
  2856.     push    cx
  2857.     call    sense_sftkey
  2858.     test    al,08h        ; GRPH is pressed ?
  2859.     jz    upone_1        ; z=no
  2860.     mov    cx,6
  2861.     call    sixel_rollup
  2862.     jmp    upone_2
  2863. upone_1:
  2864.     mov    cx,1
  2865.     call    vt100_rupn
  2866. upone_2:
  2867.     pop    cx
  2868.     pop    ax
  2869.     clc
  2870.     ret
  2871.  
  2872. dnone:
  2873.     push    ax
  2874.     push    cx
  2875.     call    sense_sftkey
  2876.     test    al,08h        ; GRPH is pressed ?
  2877.     jz    dnone_1
  2878.     mov    cx,6
  2879.     call    sixel_rolldown
  2880.     jmp    dnone_2
  2881. dnone_1:
  2882.     mov    cx,1
  2883.     call    vt100_rdnn
  2884. dnone_2:
  2885.     pop    cx
  2886.     pop    ax
  2887.     clc
  2888.     ret
  2889.  
  2890. upscn:
  2891.     push    cx
  2892.     mov    cx,24
  2893.     call    vt100_rupn
  2894.     pop    cx
  2895.     clc
  2896.     ret
  2897.  
  2898. dnscn:
  2899.     push    cx
  2900.     mov    cx,24
  2901.     call    vt100_rdnn
  2902.     pop    cx
  2903.     clc
  2904.     ret
  2905.  
  2906. gupone:
  2907.     push    cx
  2908.     mov    cx,6
  2909.     call    sixel_rollup
  2910.     pop    cx
  2911.     clc
  2912.     ret
  2913.  
  2914. gdnone:
  2915.     push    cx
  2916.     mov    cx,6
  2917.     call    sixel_rolldown
  2918.     pop    cx
  2919.     clc
  2920.     ret
  2921.  
  2922. kdos:   mov     al,'P'                  ; Push to DOS
  2923.         jmp     short cmdcom
  2924. cstatus:mov     al,'S'                  ; these commands exit Connect mode
  2925.         jmp     short cmdcom
  2926. cquit:  mov     al,'C'
  2927.         jmp     short cmdcom
  2928. cquery: mov     al,'?'
  2929.         jmp     short cmdcom
  2930. chang:  mov     al,'H'                  ; Hangup, drop DTR & RTS
  2931.         jmp     short cmdcom
  2932. trnmod:    mov    al,'M'
  2933.     jmp    short cmdcom
  2934. cmdcom: mov     kbdflg,al               ; pass char to msster.asm via kbdflg
  2935.         stc                             ; say exit Connect mode
  2936.         ret
  2937.                                         ;; end of action routines
  2938. ;
  2939. ; capture routine.
  2940. ; If capture flag is ON, put the character in AL to the file.
  2941. ;
  2942. outcapt    proc    near
  2943.         push    bx
  2944.         mov     bx,argadr               ; args from msster directly
  2945.         test    [bx].flgs,capt          ; capturing output? Can be shut off
  2946.         pop     bx                      ;  if out dev becomes not ready
  2947.         jz      outcapt1        ; no, forget this part
  2948.         push    ax                      ; save char
  2949.         call    captrtn                 ; give it captured character
  2950.         pop     ax                      ; restore character and keep going
  2951. outcapt1:
  2952.     ret
  2953. outcapt    endp
  2954.  
  2955. ;
  2956. ; Dumb terminal emulator. AL is the character to be displayed.
  2957. ; Taken from MSXGEN.ASM .
  2958. ;
  2959. dumbterm    proc    near
  2960.     cmp    vt100_lflag,(LOGCOOK_BIT+LOGENAB_BIT)    ; is cooked logging ?
  2961.     jne    dumbterm1        ; ne = no.
  2962.     call    outcapt
  2963. dumbterm1:
  2964.     test    vt100_pflag,AUTOPRINT_BIT    ; should we be printing?
  2965.     jz    dumbterm2        ; no, keep going
  2966.         push    ax
  2967.         mov     ah,LSTOUT        ; write to system printer device
  2968.         mov     dl,al
  2969.         int     dos
  2970.         pop     ax
  2971.         jnc     dumbterm2        ; nc = successful print
  2972.         push    ax
  2973.         call    beep                    ; else make a noise and
  2974.         call    trnprs                  ;  turn off printing
  2975.         pop     ax
  2976. dumbterm2:
  2977.     test    vt_ourarg.flgs,trnctl      ; debug? if so use dos tty mode
  2978.         jz      dumbterm8        ; z = no
  2979.         mov     ah,conout
  2980.         cmp     al,7fh                  ; Ascii Del char or greater?
  2981.         jb    dumbterm4        ; b = no
  2982.         je    dumbterm3        ; e = Del char
  2983.         push    ax                      ; save the char
  2984.         mov     dl,7eh                  ; output a tilde for 8th bit
  2985.         int     dos
  2986.         pop     ax                      ; restore char
  2987.         and     al,7fh                  ; strip high bit
  2988. dumbterm3:
  2989.     cmp     al,7fh                  ; is char now a DEL?
  2990.         jne    dumbterm4        ; ne = no
  2991.         and     al,3fH            ; strip next highest bit (Del --> '?')
  2992.         jmp    dumbterm5        ; send, preceded by caret
  2993. dumbterm4:
  2994.     cmp     al,' '                  ; control char?
  2995.         jae    dumbterm6        ; ae = no
  2996.         add     al,'A'-1                ; make visible
  2997. dumbterm5:
  2998.     push    ax                      ; save char
  2999.         mov     dl,5eh                  ; caret
  3000.         int     dos                     ; display it
  3001.         pop     ax                      ; recover the non-printable char
  3002. dumbterm6:
  3003.     mov     dl,al
  3004.         int     dos
  3005.         ret
  3006. dumbterm7:
  3007.     test    flags.remflg,d8bit      ; keep 8 bits for displays?
  3008.         jnz     dumbterm8        ; nz = yes, 8 bits if possible
  3009.         and     al,7fh                  ; remove high bit
  3010. dumbterm8:
  3011.     mov     ah,conout               ; dostty screen mode
  3012.         mov     dl,al                   ; write without intervention
  3013.         int     dos                     ; else let dos display char
  3014.         ret                             ; and return
  3015. dumbterm    endp
  3016.  
  3017.  
  3018. ; put the character in al to the screen, do capture and printing,
  3019. ; does translation for Set Input command.
  3020. ; Adapted from msyibm.asm [jrd]
  3021.  
  3022. outtty  proc    near
  3023.         test    flags.remflg,d8bit      ; keep 8 bits for displays?
  3024.         jnz     outnp8                  ; nz = yes, 8 bits if possible
  3025.         and     al,7fh                  ; remove high bit
  3026. outnp8:
  3027.     cmp    vt100_lflag,LOGENAB_BIT    ; raw mode logging ?
  3028.     jne    outtty_lg1        ; ne = no.
  3029.     call    outcapt            ; log it
  3030. outtty_lg1:
  3031.         cmp     rxtable+256,0           ; is translation off?
  3032.         je      outtty_knj0        ; e = yes, off
  3033.         push    bx                      ; Translate incoming char
  3034.         mov     bx,offset rxtable       ; address of translate table
  3035.         xlatb                           ; new char is in al
  3036.         pop     bx
  3037. ;
  3038. ; Kanji test. If kanji is used for receiving characters,
  3039. ; do translation for capture file, printer and display.
  3040. ; The capture file and printer use shift-JIS. On the other hand,
  3041. ; VT100 emulator ueses DEC (extended UNIX - JIS-8) code.
  3042. ;
  3043. outtty_knj0:
  3044.     cmp    kanji_rcode,KNJCODE_NONE    ; Kanji code used ?
  3045.     je    outtty_knj2        ; e = no, no translation
  3046.     cmp    kanji_rcode,KNJCODE_DEC        ; DEC (EUC) code ?
  3047.     jne    outtty_knj1        ; ne = no
  3048.     jmp    outtty_dknj0        ; jump to DEC kanji processor
  3049. outtty_knj1:
  3050.     cmp    kanji_rcode,KNJCODE_SJIS    ; Shift-JIS code ?
  3051.     jne    outtty_knj2        ; ne = no
  3052.     jmp    outtty_sknj0        ; jump to Shift-JIS process
  3053. outtty_knj2:
  3054.     jmp    outtty_trm
  3055. ;
  3056. outtty_dknj0:
  3057.     cmp    flags.vtflg,0        ; dumb terminal ?
  3058.     je    outtty_dknj1        ; e = Yes. Needs code conversion.
  3059.     jmp    outtty_trm1
  3060. outtty_dknj1:
  3061.         cmp    kanji_rmode,0        ; 2-byte code in progress ?
  3062.     je    outtty_dknj2        ; e = No, not in progress.
  3063.     mov    kanjir2,al        ; put 2nd byte
  3064.     mov    ah,al            ; prepare to conversion
  3065.     mov    al,kanjir1        ; put 1st byte
  3066.     cmp    al,08Eh            ; SS2 ?
  3067.     jne    outtty_dknj5        ; ne = No.
  3068.     mov    al,kanjir2        ; get 2nd byte
  3069.     jmp    outtty_dknj3
  3070. outtty_dknj5:
  3071.     and    ax,7f7fh        ; mask 8-th bits
  3072.     call    jis2s            ; convert to Shift-JIS
  3073.     xchg    kanjir1,al        ; save the 2byte code
  3074.     xchg    kanjir2,ah
  3075.     mov    kanjio1,ah
  3076.     mov    al,kanjir1
  3077.     call    dumbterm
  3078.     mov    al,kanjir2
  3079.     jmp    outtty_dknj3
  3080. outtty_dknj2:
  3081.     cmp    al,08Eh            ; SS2 ?
  3082.     je    outtty_dknj4        ; e = Yes.
  3083.     cmp    al,0A0h            ; is Kanji ?
  3084.     jbe    outtty_dknj3        ; z = No.
  3085. outtty_dknj4:
  3086.     mov    kanji_rmode,1        ; set multi-byte flag
  3087.     mov    kanjio1,al        ; save 1st byte
  3088.     mov    kanjir1,al
  3089.     ret
  3090. outtty_dknj3:
  3091.     call    dumbterm
  3092.     mov    kanji_rmode,0
  3093.     ret
  3094. ;
  3095. outtty_sknj0:
  3096. outtty_sknj2:
  3097.     cmp     flags.vtflg,0           ; emulating a terminal?
  3098.         jnz    outtty_sknj3        ; nz = yup, go do something smart
  3099.     call    dumbterm        ; dumb terminal emulation
  3100.     ret
  3101. outtty_sknj3:
  3102.     cmp    kanji_rmode,0        ; is it 1st byte character?
  3103.     je    outtty_sknj4        ; e = yes.
  3104.     mov    kanjio2,al        ; put 2nd byte
  3105.     mov    ah,al            ; prepare to conversion
  3106.     mov    al,kanjio1        ; put 1st byte
  3107.     call    s2jis            ; convert to JIS
  3108.     or    ax,8080h        ; use GR set
  3109.     xchg    kanjio1,al        ; save the 2byte code
  3110.     xchg    kanjio2,ah
  3111.     mov    kanjir1,ah
  3112.     jmp    outtty_trm1
  3113. outtty_sknj4:
  3114.     call    is_kanji1        ; check if kanji
  3115.     jc    outtty_sknj6        ; c = Yes.
  3116.     test    al,80h            ; katakana ?
  3117.     jz    outtty_sknj5        ; z = No.
  3118.     mov    kanji_rmode,1        ; set multi-byte flag
  3119.     mov    kanjio1,08Eh        ; SS2 code
  3120.     mov    kanjio2,al        ; extended UNIX convention
  3121. outtty_sknj5:
  3122.     jmp    outtty_trm1
  3123. outtty_sknj6:
  3124.     mov    kanji_rmode,1
  3125.     mov    kanjir1,al
  3126.     mov    kanjio1,al
  3127.     ret
  3128. ;
  3129. outtty_trm:
  3130.     cmp    flags.vtflg,0
  3131.     jne    outtty_trm1
  3132.     call    dumbterm
  3133.     ret
  3134. outtty_trm1:
  3135.     cmp    flags.vtflg,tttek
  3136.     je    outtty_tk
  3137. ;
  3138. outtty_vt:
  3139. outtty_vt1:
  3140.     cmp    kanji_rmode,0
  3141.     je    outtty_vt3
  3142. outtty_vt2:
  3143.     mov    al,kanjio1
  3144.     call    vt100
  3145.     mov    al,kanjio2
  3146. outtty_vt3:
  3147.     call    vt100
  3148. ;
  3149.     cmp    ah,0
  3150.     jne    outtty_vt4
  3151.     jmp    outtty_snd
  3152. outtty_vt4:
  3153.     push    ax
  3154.     push    dx
  3155. ;;@@    call    vt100_save
  3156.     mov    flags.vtflg,tttek
  3157.     call    ent_tk
  3158.     pop    dx
  3159.     pop    ax
  3160.     cmp    ah,2
  3161.     je    outtty_tk3
  3162.     cmp    ah,3
  3163.     jne    outtty_vt5
  3164.     mov    kanjio1,dh
  3165.     mov    kanjio2,dl
  3166.     jmp    outtty_tk2
  3167. outtty_vt5:
  3168.     jmp    outtty_snd_ex
  3169.  
  3170. outtty_tk:
  3171. outtty_tk1:
  3172.     cmp    kanji_rmode,0
  3173.     je    outtty_tk3
  3174. outtty_tk2:
  3175.     mov    al,kanjio1
  3176.     call    tek4014
  3177.     jnc    outtty_tk2_2
  3178.     jcxz    outtty_tk2_2
  3179. outtty_tk2_1:
  3180.     lodsb
  3181.     push    cx
  3182.     push    si
  3183.     call    vt100
  3184.     pop    si
  3185.     pop    cx
  3186.     loop    outtty_tk2_1
  3187. outtty_tk2_2:
  3188.     mov    al,kanjio2
  3189. outtty_tk3:
  3190.     call    tek4014
  3191.     jnc    outtty_tk3_2
  3192.     jcxz    outtty_tk3_2
  3193. outtty_tk3_1:
  3194.     lodsb
  3195.     push    cx
  3196.     push    si
  3197.     call    vt100
  3198.     pop    si
  3199.     pop    cx
  3200.     loop    outtty_tk3_1
  3201. outtty_tk3_2:
  3202. ;
  3203.     cmp    ah,0
  3204.     jne    outtty_tk4
  3205.     jmp    outtty_snd
  3206. outtty_tk4:
  3207.     push    ax
  3208.     push    dx
  3209. ;;@@    call    tek4014_save
  3210.     mov    flags.vtflg,ttvt100
  3211.     call    ent_vt
  3212.     pop    dx
  3213.     pop    ax
  3214.     cmp    ah,2
  3215.     je    outtty_vt3
  3216.     cmp    ah,3
  3217.     jne    outtty_tk5
  3218.     mov    kanjio1,dh
  3219.     mov    kanjio2,dl
  3220.     jmp    outtty_vt2
  3221. outtty_tk5:
  3222.     jmp    outtty_snd_ex
  3223. ;
  3224. outtty_snd:
  3225.     mov    kanji_rmode,0
  3226.     jcxz    outtty_snd_ex        ; If there is no answer-back, return
  3227. outtty_snd1:
  3228.     mov    ah,[si]
  3229.     call    outchr            ; send character without echo
  3230.      nop
  3231.      nop
  3232.      nop
  3233.     inc    si
  3234.     loop    outtty_snd1
  3235. outtty_snd_ex:
  3236.     ret
  3237.  
  3238. outtty  endp
  3239.  
  3240. ; send the character in al out to the serial port; handle echoing.
  3241. ; Can send an 8 bit char while displaying only 7 bits locally.
  3242. outprt  proc    near
  3243.         test    vt_ourarg.flgs,lclecho     ; echoing?
  3244.         jz      outpr1                  ; z = no, forget it
  3245.         push    ax                      ; save char
  3246.         call    outtty                  ; print it
  3247.         pop     ax                      ; restore
  3248. outpr1: mov     ah,al                   ; this is where outchr expects it
  3249.         call    outchr                  ; output to the port
  3250.         ret
  3251. outprt  endp
  3252.  
  3253. pntdead    proc    near            ; display printer is inoperative msg
  3254.     push    ax
  3255.     test    vt_ourarg.flgs,modoff    ; mode line off?
  3256.     jnz    pntdea1            ; nz = off, skip msg
  3257.     push    bx
  3258.     mov    dx,offset pntmsg    ; say printer not ready
  3259.     call    putmod            ; write on mode line
  3260.     pop    bx
  3261. pntdea1:pop    ax
  3262.     stc                ; say printer not ready
  3263.     ret
  3264. pntdead    endp
  3265.  
  3266.  
  3267. ; Get a char from the serial port manager
  3268. ; returns with carry clear if a character is available
  3269. portchr proc    near
  3270.         call    prtchr                  ; character at port?
  3271.         jc    portc2            ; no character
  3272.     and     al,parmsk               ; apply 8/7 bit parity mask
  3273.         or      al,al                   ; catch nulls
  3274.         jnz    portc2            ; nz = non null
  3275.         stc                ; ignore null
  3276. portc2: ret
  3277. portchr endp
  3278.  
  3279. ; Jump here to exit Connect mode and execute macros 'TERMINALR' (vtrmac) or
  3280. ; 'TERMINALS' (vtsmac). Does nothing if macro does not exist.
  3281. ; Preserves registers except ax. Returns to TELNET caller with 'C' in kbdflg.
  3282. vtrmac    proc    near            ; RESET macro
  3283.     mov    vtmacname,offset vtrname ; select macro name
  3284.     mov    vtmaclen,vtrlen        ; and its length
  3285.     jmp    vtmacro
  3286. vtrmac    endp
  3287.  
  3288. vtsmac    proc    near            ; SET macro
  3289.     mov    vtmacname,offset vtsname
  3290.     mov    vtmaclen,vtslen
  3291.     jmp    vtmacro
  3292. vtsmac    endp
  3293.  
  3294. ; Invoked by keyboard translator when an unknown keyboard verb is used as
  3295. ; a string definition, such as {\ktest}. Enter with vtmacname pointing to
  3296. ; uppercased verb name, asciiz, and vtmaclen set to its length.
  3297. extmacro proc    near
  3298.     jmp    vtmacro
  3299. extmacro endp
  3300.  
  3301. ;
  3302. ; Reference    Macro structure for    db    number of entries (mac names)
  3303. ;  is file     table mcctab       |->    db    length of macroname, excl '$'
  3304. ;  mssset.asm        each entry |->     db    'macroname','$'
  3305. ;  where these               |->    dw    segment:0 of definition string
  3306. ;  are stored.                      (offset part is always 0)    
  3307. ;        Definition string in     db    length of <string with null>
  3308. ;         buffer macbuf          db    'string with trailing null'
  3309. ;
  3310. vtmacro    proc    far            ; common code for macros vtsmac,vtrmac
  3311.     push    bx            ; and Product
  3312.     push    cx
  3313.     push    si
  3314.     push    di
  3315.     push    es
  3316.     mov    ax,ds
  3317.     mov    es,ax
  3318.     mov    di,offset rdbuf+1    ; macro def buffer starts here
  3319.     mov    si,vtmacname        ; pointer to macro name
  3320.     mov    cl,vtmaclen        ; length of macro name<sp/null>text
  3321.     xor    ch,ch
  3322.     mov    [di-1],cl        ; counted string field
  3323.     cld
  3324.     rep    movsb            ; copy to rdbuf
  3325.     mov    byte ptr [di],0        ; null terminator
  3326.     mov    si,offset rdbuf+1    ; look for name-text separator
  3327.     mov    cl,vtmaclen
  3328.     xor    ch,ch
  3329. vtmac1:    lodsb
  3330.     cmp    al,' '            ; space separator?
  3331.     je    vtmac1a            ; e = yes, stop here
  3332.     or    al,al            ; null terminator?
  3333.     jz    vtmac1a            ; e = yes, stop here
  3334.     loop    vtmac1
  3335.     inc    si            ; to do null lenght correctly
  3336. vtmac1a:sub    si,offset rdbuf+1+1    ; compute length of macro name
  3337.     mov    cx,si
  3338.     mov    vtmaclen,cl        ; save a macro name length
  3339.                     ; check for existence of macro
  3340.     mov    bx,offset mcctab    ; table of macro names
  3341.     mov    cl,[bx]            ; number of names in table
  3342.     xor    ch,ch
  3343.     jcxz    vtmacx            ; z = empty table, do nothing
  3344.     inc    bx            ; point to length of first name
  3345. vtmac2:    mov    al,[bx]            ; length of this name
  3346.     xor    ah,ah
  3347.     cmp    al,vtmaclen        ; length same as desired keyword?
  3348.     jne    vtmac3            ; ne = no, search again
  3349.     mov    si,bx
  3350.     inc    si            ; point at first char of name
  3351.     push    cx            ; save name counter
  3352.     push    di            ; save reg
  3353.     mov    cl,vtmaclen        ; length of name, excluding '$'
  3354.     xor    ch,ch
  3355.     mov    di,vtmacname        ; point at desired macro name
  3356.     push    es            ; save reg
  3357.     push    ds
  3358.     pop    es            ; make es use data segment
  3359.     cld
  3360.     repe    cmpsb            ; match strings
  3361.     pop    es            ; need current si below
  3362.     pop    cx
  3363.     pop    di            ; recover saved regs
  3364.     je    vtmac4            ; e = matched
  3365. vtmac3:    add    bx,ax            ; step to next name, add name length
  3366.     add    bx,4            ; + count, dollar sign, def word ptr
  3367.     loop    vtmac2            ; try next name
  3368. vtmacx:    pop    es
  3369.     pop    di
  3370.     pop    si            ; no macro, return to Connect mode
  3371.     pop    cx
  3372.     pop    bx
  3373.     ret
  3374.  
  3375. vtmac4:    cmp    taklev,maxtak        ; room in Take level?
  3376.     jge    vtmacx            ; ge = no, exit with no action
  3377.     inc    taklev            ; increment take level
  3378.     add    takadr,size takinfo    ; make a new Take entry/macro
  3379.     mov    bx,takadr        ; point to current macro structure
  3380.     mov    ax,ds            ; segment of rdbuf
  3381.     mov    [bx].takbuf,ax        ; segment of definition string struc
  3382.     mov    cl,rdbuf        ; length of whole string
  3383.     xor    ch,ch
  3384.     mov    [bx].takcnt,cx        ; number of chars in definition
  3385.     mov    [bx].takargc,0        ; our argument count
  3386.     mov    [bx].takptr,offset rdbuf+1 ; where to read next command char
  3387.     mov    [bx].taktyp,0ffh    ; flag as a macro
  3388.     pop    es
  3389.     pop    di
  3390.     pop    si
  3391.     pop    cx
  3392.     pop    bx
  3393.     jmp    endcon            ; exit Connect mode
  3394. vtmacro    endp
  3395.  
  3396. ; Error recovery routine used when outchr reports unable to send character
  3397. ;  or when vtmacro requests exiting Connect mode.
  3398. ; Exit Connect mode cleanly, despite layers of intermediate calls.
  3399. endcon    proc    near
  3400.     mov    kbdflg,'C'        ; report 'C' to TERM's caller
  3401.     mov    sp,oldsp        ; recover startup stack pointer
  3402.                     ; TERM caller's return address is now
  3403.                     ; on the top of stack. A longjmp.
  3404.     jmp    quit            ; exit Connect mode cleanly
  3405. endcon    endp
  3406. code    ends
  3407.         end
  3408.